捕获Perl eval中的变量赋值

我希望能够从Perl eval中捕获变量赋值.也就是说,确定在代码中分配了哪些变量名称并提取它们的值.

例如,如果我运行：

eval '$foo=42; $bar=3.14;'

eval的结果是3.14(评估的最后一个值),但我也希望能够确定名称“$foo”和“$bar”及其值(事先不知道名称).

我已经阅读了几种通过Safe和Eval :: Context将变量插入eval块的方法,但还没有提取它们的任何方法.我更熟悉Python的eval / exec,它已经内置了对此的支持.

解决方法

正如埃里克斯特罗姆所建议的那样,我试图根据 Safe充实解决方案.

package main;
use warnings; use strict;
use Safe;

my $cpt = new Safe;

$cpt->permit_only(qw(sassign lineseq padany const rv2sv leaveeval));
my $name_space = $cpt->root;

my $no_strict = 0;
#
# populate the clean symbol table
#
$cpt->reval('0');
die "safe compartment initialisation error: $@" if $@;
my %symtab_clean = do {no strict 'refs'; %{$name_space.'::'} }; 

my $result = $cpt->reval('$foo=42; $bar=3.14;',$no_strict);

if ($@) {
    warn "eval error: $@";
}
else {
    #
    # symbol table additions
    #
    my %symtab_dirty = do {no strict 'refs'; %{$name_space.'::'} }; 

    my @updated_variables = grep { ! exists $symtab_clean{$_} } (sort keys %symtab_dirty);

    foreach my $variable (@updated_variables) {
        my $value = do{ no strict 'refs'; ${$name_space.'::'.$variable} };
       print "variable $variable was set to: $value\n"
    }
}

笔记：

>以上允许最小限制的saf操作码组.见perl opcodes>我选择在执行命令之前和之后查找差异