可以修改通过“地址属性”传递给过程的变量吗？

如何解决可以修改通过“地址属性”传递给过程的变量吗？

在下面的测试代码中，我试图通过将变量作为 system.address 传递给另一个过程来修改变量。

with Ada.Text_IO;
with System;
with System.Storage_Elements;


procedure Main is
  
  procedure Modify ( Var : in out System.Address) is
    use System.Storage_Elements;
  begin
    Var := Var + 10;
  end Modify;
  
  My_Var : Integer := 10; 
begin
  --  Insert code here.
  Modify (My_Var'Address);
  Ada.Text_IO.Put_Line("My_Var is:" & Integer(My_Var)'Image ); 
  
end Main;

编译器返回如下错误，

17:17 actual for "Var" must be a variable

我无法理解原因，因为 My_Var(actual for Var) 显然是一个变量。我应该更改什么以使用 system.address 修改 My_Var？

注意：这条线索的上下文是我试图理解现有遗留项目中的接口模块。虽然可能有更好的方法来实现我的需要，但我想了解是否可以使用上述方法修改变量。

解决方法

您修改的是地址而不是变量。尝试将参数更改为 Addr : in System.Address 并在 Var : Integer with Address => Addr 中声明 Modify。

,

如果您能展示旧界面模块的相关部分会很有帮助——这将有助于我们了解您需要什么和想要做什么。

也就是说，首先要注意的是，在 Ada 中通过引用传递参数通常不是通过显式传递“实际变量的地址”来完成的。正如您所说，还有其他更好的方法。

如果您传递一个 System.Address 值，然后想要读取或写入驻留在该地址的任何数据，则必须通过强制拥有该地址的变量或通过访问值来执行读/写操作（Ada 相当于“指针”），您强制指向该寻址位置。在这两种情况下，您都有责任确保变量或访问值的类型与您要读取或写入的数据的实际类型相匹配。

要创建指向给定地址处的内存的访问值，您应该使用预定义的包 System.Address_To_Access_Conversions。这需要对访问值和泛型有一定的了解，因此我不会在此处展示示例。

要强制变量具有给定地址，请声明变量并将地址方面设置为给定地址。下面的代码展示了如何在这个例子中做到这一点。请注意局部变量 Modify.Var 的声明（并注意我将参数名称从 Var 更改为 Var_Addr）。

with Ada.Text_IO;
with System;

procedure Mod_By_Addr is

  procedure Modify (Var_Addr : in System.Address) is
    Var : Integer with Address => Var_Addr;
  begin
    Var := Var + 10;
  end Modify;

  My_Var : aliased Integer := 10;

begin
  Modify (My_Var'Address);
  Ada.Text_IO.Put_Line("My_Var is:" & Integer(My_Var)'Image );

end Mod_By_Addr;

由于在 Modify 过程中没有修改 Var_Addr 参数，所以它可以用“in”方式声明，因此实际参数可以是一个表达式（My_Var'Address）。

HTH

,

我所理解的使用 address_to_Access_Conversions 修改变量的另一种方法如下所示，

with Ada.Text_IO;
with System.Address_To_Access_Conversions;
with System.Storage_Elements;

procedure Main is

  procedure Modify ( Var : in System.Address) is
    use System.Storage_Elements;
    package Convert is new System.Address_To_Access_Conversions (Integer);
  begin
    Ada.Text_IO.Put_Line(Convert.To_Pointer (Var).all'Img);
  end Modify;

  My_Var : Integer := 10;
begin
  Modify (My_Var'Address);
  Ada.Text_IO.Put_Line("My_Var is:" & Integer(My_Var)'Image );

end Main;