微信公众号搜"智元新知"关注
微信扫一扫可直接关注哦！

LMC 中的输出和复位列表

分类：编程问答

如何解决LMC 中的输出和复位列表

我正在处理这个编码挑战：

为 Little Man Computer 编写一个程序，允许用户管理值列表。它应该以一个空列表开始，然后按如下方式处理输入：

如果输入是：

  • 小于 100：将此值添加到列表中，除非列表已有 10 个值，在这种情况下该值将被忽略
  • 995：将列表清空
  • 996：输出列表当前具有的值的数量
  • 997：按照添加到列表中的顺序输出列表当前具有的每个值
  • 998：以相反的顺序输出列表当前具有的每个值
  • 999：结束程序
  • 忽略任何其他值

只要输入值不是 999，输入值的处理就会继续。

当输入 997 时，我在获取代码以按正向顺序打印存储的列表时遇到问题。我想我可能混淆了 ADD 和 SUB 指令。当输入 995 时，我也无法正确重置存储列表。

我能够正确编程的其他一切。

下面是我的代码：

START   INP
        STA TEMP
        SUB NInes
        BRZ end

        LDA TEMP
        SUB EIGHT
        BRZ PRIT

        lda temp
        sub seven
        brz printf

        LDA TEMP
        SUB SIX
        BRZ DOOUT

        LDA TEMP
        SUB FIVE
        BRZ RESET

        LDA COUNT
        SUB TEN
        BRZ START

        LDA TEMP
        SUB HUND
        BRP START

SIT     LDA SINST
        ADD COUNT
        STA SLOC
        LDA TEMP
SLOC    DAT 0
        LDA COUNT
        ADD ONE
        STA COUNT
        BRA START
PRIT    LDA COUNT
        BRZ END
PRINTR  LDA LINST
        ADD COUNT
        SUB ONE
        STA LDIT
LDIT    DAT 0
        OUT
        LDA COUNT
        SUB ONE
        STA COUNT
        BRZ END
        BRA PRINTR

---PRINTF  LDA LINST
        ADD COUNT
        add ONE
        STA LDIT
LDIT    DAT 0
        OUT
        LDA COUNT
        SUB ONE
        STA COUNT
        BRZ END
        BRA PRINTF 

doout   lda count
        out
        bra start

reset   lda zero
        sta count
        bra start

END     HLT

TEMP    DAT 0
COUNT   DAT 0
ONE     DAT 1
TWO     DAT 2
TEN     DAT 10
HUND    DAT 100
SINST   DAT 380
LINST   DAT 580
five    dat 995
six     dat 996
seven   dat 997
eight   dat 998
NInes   DAT 999

解决方法

您的程序中的问题可以归类为：

  1. 良好的模拟器在运行程序之前应检测到的与标签相关的问题
  2. 与程序逻辑相关的问题，导致程序产生错误的输出
  3. 与代码风格相关的问题

1.标签

一个好的模拟器不应该接受以下错误：

  • PRINTF 标签未定义。

    有一个 brz printf 指令，但该标签未定义，因为 --- 使其成为注释。显然，需要删除 --- 才能使标签引用有效。

  • LDIT 标签重复：

    标签 LDIT 被定义了两次。这将产生不可靠的行为。一个好的模拟器应该给出一个关于这个的错误信息，但其他模拟器只会采用一个定义并忽略重复项。无论哪种方式，该程序的意图是一个 STA LDIT 使用 first LDIT 位置，第二个 STA LDIT 使用 second LDIT 位置。如果有的话，这将不会发生。因此，重命名两个标签之一，并相应地调整 STA LDIT 指令之一。

  • zero 标签未定义：

    重置计数器的代码引用了未定义的标签 zero。同样，好的模拟器在加载程序时会产生错误，但其他模拟器可能会默默地使用邮箱 0，这会导致不良行为。因此将 zero 标签定义为

    zero DAT 0

2.逻辑

  • 用于打印列表的代码，无论是向前还是向后，都改变 COUNT 的值，但是这样代码会丢失什么是列表的大小！例如，如果在这样的遍历之后你会选择动作 996——即查询列表的大小——它不会给出正确的结果。解决方案是使用一个不同变量来遍历列表，并保持COUNT不变。 COUNT 只应在您添加一个值到列表中或当您重置列表时更改。

  • 打印代码以跳转到 END 结束，但似乎应该允许用户继续使用另一个“菜单”选项，因此不应跳转到 END跳到START。跳转到 END 的唯一原因应该是因为用户输入了选项 999。

  • 对于 forward 打印，您不应该在动态加载指令中添加 COUNT，因为您需要从 first 元素开始列表，而不是最后一个。所以在第一次打印之前不要做 ADD COUNT 或 ADD ONE。相反，增加动态加载指令，直到它与原始加载指令的差异——即计算列表中的相对偏移——至少为 COUNT。

  • LMC 规范有一个特别奇怪的地方：它没有定义当减法会导致负结果时累加器的值是多少。累加器不能存储负值，只能标记一个负值。因此，当您刚刚执行了可能导致负值的 BRZ 指令时，执行 SUB 是不安全的（因为奇怪的是，模拟器可能对当减法为负时，累加器中的值为零）。简而言之，如果可以，最好使用 BRP 而不是 BRZ，或者在使用 BRP 之前最少使用 BRZ。注意：即使是这门学科的教师也并不总是意识到这一点。

  • LMC 有一个重置“句柄”，它将程序计数器设置回程序的开始。发生这种情况时，您需要从头开始，并将 COUNT 重置为 0。因此，在程序的最顶部添加重置代码。

这将解决您程序中的语义问题。

3.代码风格

  • 我建议您使用更有意义的名称。 doout 不是很有启发性，因为您的程序被设计为输出不同的东西（前序列表、后序列表、列表大小）。例如，使用 output_size 而不是 doout。像 LDIT、PRIT、... 这样的名称非常神秘。如果程序使用描述性名称，而不使用只有您才能理解的缩写，它会更容易阅读和理解。

  • 动态指令基于SINST（存储指令）和LINST（加载指令），硬编码为：

    SINST  DAT 380
LINST  DAT 580

    但是很遗憾你把它们硬编码成那样。首先，他们假设邮箱 80 可以免费存储列表，其次它需要了解这些指令（3 和 5）的操作码。然而，有了好的汇编程序，您就不必这样做了。所以我建议改为这样做：

    store_instruction STA list
load_instruction  LDA list

    ...并在代码的最底部使用 list 指令定义 DAT （因为那里有可用的邮箱）。我什至会在它后面添加虚拟的 DAT 行，以便非常清楚属于该列表的邮箱——它只是让某人更容易理解代码：

    list DAT
     DAT
     DAT
     DAT
     DAT
     DAT
     DAT
     DAT
     DAT
     DAT

    这样，列表可能不会存储在邮箱 80，但我们不在乎。我们把它留给汇编器来为我们的列表分配下一个空闲邮箱。在“数据部分”中间放置 STA 和 LDA 指令也可能看起来很奇怪，它们永远不会被执行，但 LMC 架构（冯诺依曼架构）的原理是代码和数据使用相同的内存，所以这很好。 LDA 和 STA 指令将从那里复制到实际程序中。

修正程序

考虑到以上所有因素，该程序可能如下所示：

#input:1 2 3 997 998 999
clear_list        LDA zero # Start by resetting the list
                  STA list_size

start             INP
                  STA input
                  SUB menu_nine
                  BRP end

                  LDA input
                  SUB menu_eight
                  BRP output_reversed

                  LDA input
                  SUB menu_seven
                  BRP output_forward

                  LDA input
                  SUB menu_six
                  BRP output_size

                  LDA input
                  SUB menu_five
                  BRP clear_list

                  LDA list_size
                  SUB max_list_size
                  BRP start

                  LDA input
                  SUB input_limit
                  BRP start

                  LDA store_instruction
                  ADD list_size
                  STA store
                  LDA input
store             DAT 0
                  LDA list_size
                  ADD one
                  STA list_size
                  BRA start

output_reversed   LDA load_instruction
                  ADD list_size
loop_reversed     SUB one
                  STA load_reversed
                  SUB load_instruction # are we still within the list?
                  BRP load_reversed # yes,continue printing
                  BRA start
load_reversed     DAT 0
                  OUT
                  LDA load_reversed # decrement the dynamic LDA instruction
                  BRA loop_reversed

output_forward    LDA load_instruction
loop_forward      STA load_forward
                  SUB load_instruction # get relative offset in the list
                  SUB list_size # are we still within the list?
                  BRP start # no,stop printing
load_forward      DAT 0
                  OUT
                  LDA load_forward # increment the dynamic LDA instruction
                  ADD one
                  BRA loop_forward

output_size       LDA list_size
                  OUT
                  BRA start

end               HLT

# constants
zero              DAT 0
one               DAT 1
two               DAT 2
max_list_size     DAT 10
input_limit       DAT 100
load_instruction  LDA list
store_instruction STA list
menu_five         DAT 995
menu_six          DAT 996
menu_seven        DAT 997
menu_eight        DAT 998
menu_nine         DAT 999
# variables
input             DAT 0
list_size         DAT 0
list              DAT
                  DAT
                  DAT
                  DAT
                  DAT
                  DAT
                  DAT
                  DAT
                  DAT
                  DAT



<script src="https://cdn.jsdelivr.net/gh/trincot/lmc@v0.816/lmc.js"></script>

您可以使用此代码段直接在此处运行代码。点击Run Code Snippet激活一个LMC模拟器，然后使用右侧的面板与之交互。

版权声明：本文内容由互联网用户自发贡献，该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容， 请发送邮件至 dio@foxmail.com 举报，一经查实，本站将立刻删除。

苹果市值2025年有望达4万亿美元
pythonJavaScriptjavaHTMLPHPreactjsC#AndroidCSSNode.jssqlrpython-3.xMysqLjQueryc++pandasFlutterangularIOSdjangolinuxswifttypescript路由器JSON路由器设置无线路由器h3c华三华三路由器设置华三路由器电脑软件教程arraysdocker软件图文教程Cvue.jslaravelspring-boot