在 Common Lisp 中使用没有身体表达式的 do* 是否被认为是一种不好的做法？

如何解决在 Common Lisp 中使用没有身体表达式的 do* 是否被认为是一种不好的做法？

我正在尝试通过Common Lisp：符号计算的温和介绍这本书来学习 Common Lisp。此外，我正在使用 SBCL、Emacs 和 Slime。

在第 11 章中，作者介绍了用于迭代的 do* 函数。之前，这本书展示了 do 函数的模板：

(DO ((var1 init1 [update1])
     (var2 init2 [update2])
     ...)
    (test action-1 ... action-n)
 body)

这本书没有显示do*的模板。可能是因为它是相同的，尽管 do 和 do* 之间存在差异。

在练习 11.11 中，这本书问：

11.11 Rewrite the following function to use DO* instead of DOLIST.

(defun find-largest (list-of-numbers)
  (let ((largest (first list-of-numbers)))
    (dolist (element (rest list-of-numbers)
                     largest)
      (when (> element largest)
        (setf largest element)))))

这是答卷中的实现：

(defun do*-find-largest-answer-sheet (list-of-numbers)
  (do* ((largest (first list-of-numbers))
        (z (rest list-of-numbers) (rest z))
        (element (first z) (first z)))
       ((null z) largest)
    (when (> element largest)
      (setf largest element))))

我的实现返回了正确的结果，但风格不同：

(defun do*-find-largest (list-of-numbers)
  (do* ((x list-of-numbers (rest x))
        (e (first x) (first x))
        (largest (car list-of-numbers) (if (> e largest) e largest)))
       ((null (rest x)) (return largest))))

如您所见，与本书的答案不同，我不在通常为身体表达保留的空间中使用任何东西。另外，我在局部变量更新中插入了条件表达式。我喜欢我的方法更短的事实。

我的方法在 Common Lisp 中会被认为是一种糟糕的风格或糟糕的实践吗？可以接受吗？

既然“你不知道你不知道什么”，那么我的实现有什么我不知道的缺点吗？

解决方法

通常，这不被认为是不好的做法。但是，您应该避免仅仅因为您不想要 do(*) 主体而过于复杂的更新和结束测试。

编写一个没有主体的 do* 循环并没有错。这是一个替代版本：

(defun do*-find-largest (list-of-numbers)
  (do* ((x list-of-numbers (cdr x))
        (largest (car x) (max largest (car x))))
       ((null (cdr x)) largest)))