smalltalk 中的二分搜索

如何解决smalltalk 中的二分搜索

Array extend [
   Array class >> bin: val left: l right: r [
      ^ super binSearch: val left: l right: r
   ]

   binSearch: val left: l right: r [
      |arr iter|
      arr := self.
      [l == r]
         ifTrue: [^ (-1)].
      iter := (r + l)/2.
      [arr at: iter == val]
         ifTrue: [^iter].
      [arr at: iter < val]
         ifTrue:[^ super binSearch val left: l right: iter]
         ifFalse: [^ super binSearch val left: iter right: r]
   ]
]
arr := #(3 6 9 10).
arr bin: 6 left: 1 right: 4.

这是我当前的代码，但出现编译错误：“对象：新数组：4“”错误：不理解#bin:left:right:”。我想知道我做错了什么。

谢谢

解决方法

第一部分对我来说毫无意义。你的算法是递归的，所以它应该调用自己而不是委托给类，这是一个不同的对象。

为此，将 super 替换为 self，然后将使用新参数再次调用相同的方法。

Array extend [
   binSearch: val left: l right: r [
      |arr iter|
      arr := self.
      l = r
         ifTrue: [^ -1].
      iter := (r + l) // 2.
      (arr at: iter) = val
         ifTrue: [^iter].
      (arr at: iter) < val
         ifTrue:[^ self binSearch: val left: l right: iter]
         ifFalse: [^ self binSearch: val left: iter right: r]
   ]
]

补充说明

[Boleans] ifTrue: 和朋友的接收者必须是 Boolean（即 true 或 false）。通过将条件括在方括号之间，您将创建一个 BlockClosure。我已经在适当的情况下将 [...] 替换为 (...)，然后在不需要时将其删除（请参阅下面的 [优先级]）。
[比较] 这是有争议的，但是，虽然条件 l==r 并非完全错误，但是，l=r 通常更好。原因：== 的语义对应于完全相同的对象（低级），= 的语义是相等（或等效）。您的算法不关心 l 和 r 是否由完全相同的对象表示，它只需要知道两个变量是否持有相同的整数。尽管在这种情况下区别并不重要，但您可能会养成使用 == 的习惯，这在您处理其他类型的对象（例如 LargeIntegers 等）时会失败
[括号] 无需在 ^ -1 中添加括号。
[Division] 由于 + 和 / 是消息，因此无需在 r + 1 / 2 中添加括号。但是，除法可能会产生 Fraction，其中您的代码需要 Integer。使用 // 来获取商。
[冒号] 您忘记了 binSearch 后面的冒号。这会产生 DNU 错误。
[Precedence] arr at: iter 周围需要括号，以便将此消息的结果与 val 进行比较（回想一下优先顺序是：一元、二元,关键字）。
[DNU] 关于您得到的错误：您创建的选择器是 binSearch:left:right:，但是您发送的消息 bin:left:right: 未定义。 >
[self] 不需要将 self 分配给其他东西：接收者不会随着递归而改变。
[Return] 许多 Smalltalker 应该将返回符号 ^ 移到最后一个表达式的开头。
在 Smalltalk 中，数组是从 1 开始的，广泛接受的约定是在找不到索引时返回 0（而不是 -1）。

Array extend [
   binSearch: val left: l right: r [
      | iter |
      l = r ifTrue: [^ 0].
      iter := (r + l) // 2.
      (self at: iter) = val ifTrue: [^iter].
      ^ (self at: iter) < val
         ifTrue:[self binSearch: val left: l right: iter]
         ifFalse: [self binSearch: val left: iter right: r]
   ]
]

建议

通过添加足够的单元测试来练习和改进您的方法来完成您的工作。我的回答仅限于编码风格，而不是其正确性。
添加以下方法，以便您的服务的客户端在使用它时不需要冗长。

binSearch: value
  ^self binSearch: value left: 1 right: self size

考虑将选择器更改为更具可读性的内容。您的选择器不是一个句子，而是一种命名参数的方式。怎么样？

binarySearch: value from: left to: right