突然运行时错误 13 无缘无故

如何解决突然运行时错误 13 无缘无故

多年来我一直在使用修改过的匹配函数，效果很好。但是突然我无缘无故地收到运行时错误 13。这个函数在实际过程中在错误弹出之前被调用了两次。第一次一切正常，第二次出现错误。代码如下：

Public Function xMatch(ByRef Direction_Range As Range,ByVal Find_Value_Or_String,Occ_Number As Integer,Row_True_Or_Column_False As Boolean,RelativePosition_True_Or_AbsolutePosition_False As Boolean) As Integer
Dim xMTcell
toolVar1 = 0
xMatch = 0
occurrencesCount = 0
If RelativePosition_True_Or_AbsolutePosition_False = True Then
    If Row_True_Or_Column_False = True Then
        toolVar1 = Range(Split(Direction_Range.Address,":")(0)).Row - 1
    Else
        toolVar1 = Range(Split(Direction_Range.Address,":")(0)).Column - 1
    End If
End If
For Each xMTcell In Direction_Range
    If xMTcell.Value = Find_Value_Or_String Then
        occurrencesCount = occurrencesCount + 1
        If occurrencesCount = Occ_Number Then
            If Row_True_Or_Column_False = True Then
                xMatch = xMTcell.Row - toolVar1
            Else
                xMatch = xMTcell.Column - toolVar1
            End If
            Exit For
        End If
    End If
Next xMTcell
End Function

toolVar1 和occurrencesCount 在模块中声明。该函数可以在任何范围（Direction_Range）中搜索并找到值（Find_Value_Or_String）。与常规匹配函数相反，如果该范围内有多个匹配函数，您可以决定 (Occ_Number) 哪个查找将是您需要的。此外，您可以决定是否需要该查找的行或列，以及是否需要该行/列的绝对值（与工作表相比的位置）或相对（与 Direction_Range 相比的位置）。

错误出现在这一行：

If xMTcell.Value = Find_Value_Or_String Then

因为 xMTcell 是 Direction_Range 的一部分，所以我检查了范围，它显然是正确的，而且它是一个范围，没有别的。我还检查了值，这是他正在寻找的字符串，可以在该范围内手动找到。我不明白为什么它在使用完全相同类型的 Direction_Range 和 Find_Value_Or_String 的过程的其他阶段工作正常，但突然就不行了。我已经尝试将 xMTcell 声明为范围，但没有任何区别。

有人有想法吗？

问候卡尔

根据评论，我做了以下检查：

Debug.Print VarType(Direction_Range)
Debug.Print Direction_Range.Address
Debug.Print VarType(xMTcell.Value)
Debug.Print VarType(Find_Value_Or_String)
Debug.Print xMTcell.Address

对于我得到的非窃听过程


8204
$A$4:$N$4
8
8
$B$4

以及窃听过程

8204
$A$5:$A$16
8204
8
$A$5:$A$16

所以它的范围有问题，为什么它的行为不同？

解决方法

TL;DR：

将 For Each xMTcell In Direction_Range 更改为 For Each xMTcell In Direction_Range.Cells。

一些调试和一般提示（总结评论和您在其中的反馈）：

Dim xMTcell - 使其成为 Range。
使用 Debug.Print (Control+G 调出立即窗口并检查输出)。
Debug.Print VarType(xMTcell.Value) 返回 8204：根据 VarType 文档，这意味着 xMTcell.Value 是 vbArray 的 vbVariant (8192 + 12 = 8204）。
Debug.Print VarType(Find_Value_or_String) 返回 8：再次根据 VarType 文档，这意味着 Find_Value_or_String 是 String。
类型不匹配是因为您无法将 String 与数组进行比较。
xMTCell.Value 是一个数组这一事实表明 xMTCell 是一个多单元格范围，而不是一个单元格。
... 由 Debug.Print xMTcell.Address 的输出验证为多单元格范围。
最有可能的问题是您传递了 Row 或 Column 作为您的 Direction_Range，即您使用 Rows 或 Columns 返回一个范围。循环遍历 Row 或 Column 时，您需要指定循环遍历单个单元格。

突然运行时错误 13 无缘无故

如何解决突然运行时错误 13 无缘无故

解决方法

相关推荐