如何使用 XSLT 将 JSON 转换为 XML？

如何解决如何使用 XSLT 将 JSON 转换为 XML？

我想使用 XSLT 将 JSON 转换为 XML。但无法达到预期的输出。 以下是 JSON 请求：

{
    "Store": [
        {
            "Book": "Cartoons","ID": "ABC"
        }
    ]
}

我尝试过的 XSLT：

 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:math="http://www.w3.org/2005/xpath-functions/math"
    xmlns:xd="http://www.oxygenxml.com/ns/doc/xsl"
    xmlns:emp="http://www.semanticalllc.com/ns/employees#"
    xmlns:h="http://www.w3.org/1999/xhtml"
    xmlns:fn="http://www.w3.org/2005/xpath-functions"
    xmlns:j="http://www.w3.org/2005/xpath-functions"
    exclude-result-prefixes="xs math xd h emp"
    version="3.0"
    expand-text="yes">

<xsl:template match="/">
    <xsl:copy>
        <xsl:apply-templates select="json-to-xml(.)/*"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[@key]" xpath-default-namespace="http://www.w3.org/2005/xpath-functions">
    <xsl:element name="{@key}">
        <xsl:apply-templates/>
    </xsl:element>
</xsl:template>

</xsl:stylesheet>

但我得到的是空响应。

解决方法

您需要将 JSON 作为参数传递或从文件中读取它，XSLT 的输入是 XML 或者您可以从命名模板开始：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="#all"
    version="3.0">
    
  <xsl:param name="json" as="xs:string" expand-text="no">{
    "Store": [
        {
            "Book": "Cartoons","ID": "ABC"
        }
    ]
}</xsl:param>

  <xsl:output indent="yes"/>

  <xsl:template match="/" name="xsl:initial-template">
      <xsl:sequence select="json-to-xml($json)"/>
  </xsl:template>
  
</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/93wniTJ

您的样本的函数结果是

<map xmlns="http://www.w3.org/2005/xpath-functions">
   <array key="Store">
      <map>
         <string key="Book">Cartoons</string>
         <string key="ID">ABC</string>
      </map>
   </array>
</map>

当然，您可以通过其他模板运行它以将其转换为不同的格式。

,

模式 match="/" 匹配文档节点（XML 树的根）。如果输入是 JSON，它将与您的输入不匹配。

XSLT 3.0 实际上并不擅长使用模板规则处理 JSON：它可以完成，但不是很方便。通常使用函数更方便。您可以提供 JSON 输入作为 xsl:param 的值，并在 xsl:initial-template 的代码中处理它；或者，如果您感觉更有野心，您实际上可以通过调用将 JSON 输入作为参数的公共 xsl:function 来启动 XSLT 处理。

样式表的传统 match="/" 条目仅适用于 XSLT 处理 XML 输入文档的传统用途。