如何解决图的密码查询
如何确定图中每个节点的入度和出度以及总度数。此外,图的最长路径因此图的直径和图的密度。最后两个问题是每种类型的关系数,以及每个标签的每个标签的节点数。
我使用这个查询来加载数据集:
LOAD CSV WITH HEADERS FROM 'file:///vgsales.csv' AS line
CREATE (v:Vgsales {
rank: toInteger(line.Rank),name: line.Name,platform: line.Platform,year: toInteger(line.Year)
})
MERGE (g:GENRE {genre: line.Genre})
MERGE (p:PUBLISHER {
publisher: line.Publisher,NA_sales: toInteger(line.NA_Sales),EU_sales: toInteger(line.EU_Sales),JP_sales: toInteger(line.JP_Sales),Other_sales: toInteger(line.Other_Sales),Global_sales: toInteger(line.Global_Sales)
})
MERGE (v)-[:IN_GENRE]->(g)
MERGE (p)-[:PUBLISHED]->(v)
解决方法
对于一个节点,您可以使用 size(<pattern>)
来查找模式的度数(前提是没有为另一个节点提供标签,并且模式中不存在任何属性,因为那些需要实际扩展路径才能找到并过滤这些东西)。
因此要获取图中所有节点的所有进出度,您可以使用:
MATCH (n)
RETURN id(n) as id,size((n)-->()) as outDegree,size((n)<--()) as inDegree
图的直径是每个节点之间所有最短路径中最长的,因此需要两个节点的每个组合首先得到最短路径,然后只取最长的:
MATCH (n)
WITH collect(n) as allNodes
UNWIND allNodes as a
UNWIND allNodes as b
WITH a,b
WHERE id(a) < id(b)
MATCH path = shortestPath((a)-[*]-(b))
RETURN max(length(path)) as diameter
id(a) < id(b)
限制是为了确保我们过滤掉 a 和 b 是同一节点的行,并过滤掉镜像结果,因为我们只想要 a 和 b 的单一组合(而不是计算第二个a 和 b 交换的时间)。
对于每个关系的计数,以及按标签的节点计数,这些都存储在计数存储中,访问这些统计信息的最简单方法是通过 APOC 过程。这可以预先捆绑,检查此安装页面(更改您在 url 中使用的次要版本以获取更具体的说明):
https://neo4j.com/labs/apoc/4.1/installation/
安装后,您可以使用 CALL apoc.meta.stats()
访问所有图形计数。 nodeCount
列将为您提供图表中的总节点数,而 labels
列将为您提供每个标签的计数。 relTypesCount
列将为您提供每种关系类型的计数。
我相信对于图密度,对于有向图,它是 E / (V (V - 1))
,其中 E 是总边数,V 是总顶点数。我们可以从计数存储中获取这些并使用该公式:
CALL apoc.meta.stats() YIELD nodeCount,relCount
RETURN toFloat(relCount) / (nodeCount * (nodeCount - 1)) as density
版权声明:本文内容由互联网用户自发贡献,该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务,不拥有所有权,不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容, 请发送邮件至 dio@foxmail.com 举报,一经查实,本站将立刻删除。