Wikidata/SPARQL，在结果中获取不同的项目对象 ID

如何解决Wikidata/SPARQL，在结果中获取不同的项目对象 ID

当我运行以下查询时，我得到了多行“Paul Gauguin”，因为关于他的死亡地点/时间有多种信息，同样的情况当然也可能发生在所有其他参数上。

   SELECT disTINCT ?item ?itemLabel ?itemDescription ?birthplaceLabel ?birthdate ?deathplaceLabel ?deathdate ?imageLabel ?article ?articleEn
{
  ?item wdt:P31 wd:Q5.
  ?item wdt:P119 wd:Q5024152.
  
  OPTIONAL {
    ?item wdt:P18 ?image.       
  }
  OPTIONAL {
    ?item wdt:P19 ?birthplace.
  }
  OPTIONAL {
    ?item wdt:P569 ?birthdate.    
  }
  OPTIONAL {
    ?item wdt:P20 ?deathplace.    
  }
  OPTIONAL {
    ?item wdt:P570 ?deathdate.
  }
  OPTIONAL {
     ?article schema:about ?item.
     ?article schema:isPartOf <https://sv.wikipedia.org/>.
  }
   OPTIONAL {
     ?articleEn schema:about ?item.
     ?articleEn schema:isPartOf <https://en.wikipedia.org/>.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "sv,en,[AUTO_LANGUAGE]". }
}

有没有办法只接收一个相同的对象 id，而不关心是否有其他“版本”的对象。

我尝试了一些嵌套查询，但我无法让它工作。还有其他方法吗？

解决方法

此查询将起作用：

SELECT DISTINCT ?item ?itemLabel ?itemDescription 
(SAMPLE(?birthplaceLabel) AS ?birthplaceLabel)
(SAMPLE(?birthdate) AS ?birthdate)
(SAMPLE(?deathplaceLabel) AS ?deathplaceLabel)
(SAMPLE(?deathdate) AS ?deathdate)
(SAMPLE(STR(?image)) AS ?image)
?article ?articleEn

WHERE {
  ?item wdt:P31 wd:Q5.
  ?item wdt:P119 wd:Q5024152.
  
  OPTIONAL {
    ?item wdt:P18 ?image.       
  }
  OPTIONAL {
    ?item wdt:P19 ?birthplace.
  }
  OPTIONAL {
    ?item wdt:P569 ?birthdate.    
  }
  OPTIONAL {
    ?item wdt:P20 ?deathplace .    
  }
  OPTIONAL {
    ?item wdt:P570 ?deathdate.
  }
  OPTIONAL {
     ?article schema:about ?item.
     ?article schema:isPartOf <https://sv.wikipedia.org/>.
  }
   OPTIONAL {
     ?articleEn schema:about ?item.
     ?articleEn schema:isPartOf <https://en.wikipedia.org/>.
  }
  SERVICE wikibase:label {  ?birthplace rdfs:label ?birthplaceLabel . 
                          ?deathplace rdfs:label ?deathplaceLabel .
                          ?item rdfs:label ?itemLabel ;
                                schema:description ?itemDescription .
                          bd:serviceParam wikibase:language "sv,en,[AUTO_LANGUAGE]". }
}
GROUP BY ?item ?itemLabel ?itemDescription ?article ?articleEn

如您所见，我们使用 SAMPLE 函数并按所有未采样的变量进行分组。 如果您希望查看属性采用的所有可能值，也可以将 SAMPLE 替换为 GROUP_CONCAT。 例如。 ... (GROUP_CONCAT(?deathdate; SEPARATOR="; ") AS ?deathdates) ...

请注意，GROUP_CONCAT 将字符串作为参数。

,

对 Valerio Cocchis 的答案稍加修改，找到了解决方案。

SELECT ?item ?itemLabel ?itemDescription 
(SAMPLE(?birthplaceLabel) AS ?birthplaceLabel)
(SAMPLE(?birthdate) AS ?birthdate)
(SAMPLE(?deathplaceLabel) AS ?deathplaceLabel)
(SAMPLE(?deathdate) AS ?deathdate)
(SAMPLE(?imageLabel) AS ?imageLabel)
?article ?articleEn

WHERE {
  ?item wdt:P31 wd:Q5.
  ?item wdt:P119 wd:Q5024152.
  
  OPTIONAL {
    ?item wdt:P18 ?image.       
  }
  OPTIONAL {
    ?item wdt:P19 ?birthplace.
  }
  OPTIONAL {
    ?item wdt:P569 ?birthdate.    
  }
  OPTIONAL {
    ?item wdt:P20 ?deathplace.    
  }
  OPTIONAL {
    ?item wdt:P570 ?deathdate.
  }
  OPTIONAL {
     ?article schema:about ?item.
     ?article schema:isPartOf <https://sv.wikipedia.org/>.
  }
   OPTIONAL {
     ?articleEn schema:about ?item.
     ?articleEn schema:isPartOf <https://en.wikipedia.org/>.
  }
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "sv,[AUTO_LANGUAGE]". 
    ?birthplace rdfs:label ?birthplaceLabel . 
    ?deathplace rdfs:label ?deathplaceLabel .
    ?image rdfs:label ?imageLabel .
    ?item rdfs:label ?itemLabel .
    ?item schema:description ?itemDescription .
  }
}
GROUP BY ?item ?itemLabel ?itemDescription ?article ?articleEn