如何解决当绘图本身具有透明度时,如何使 Gnuplot 中绘图的键不具有透明度?
我正在尝试制作一个“密度”类型的散点图,其中每个点都是一个透明的圆圈,因此当它们重叠时,它会形成一个密度图。我正在使用大量样本进行此操作,因此透明度非常低,但这意味着不可能看到关键。我可以使密钥的透明度与实际绘图不同吗?
这就是我所拥有的:
if (!exists("outfile")) outfile='plot.pdf'
set terminal pdf enhanced size 8in,4.8in
set output outfile
set style fill transparent solid 0.1 noborder
set style circle radius 0.03
plot sample1 u 1:2 w circles,sample2 u 1:2 w circles
解决方法
只需使用 keyentry
和 with points pt 7
。检查help keyentry
。
代码:
### keyentry
reset session
# create some random test data
set samples 10000
set table $Data1
plot '+' u (invnorm(rand(0))+1):(invnorm(rand(0))+1) w table
set table $Data2
plot '+' u (invnorm(rand(0))+4):(invnorm(rand(0))+4) w table
unset table
set style fill transparent solid 0.1 noborder
set style circle radius 0.03
plot $Data1 u 1:2 w circles notitle,\
$Data2 u 1:2 w circles notitle,\
keyentry w p pt 7 lc 1 title "Data1",\
keyentry w p pt 7 lc 2 title "Data2"
### end of code
对于较旧的“pre-keyentry”gnuplot 版本,您可以通过以下方式交换 keyentry
行:
NaN w p pt 7 lc 1 title "Data1",\
NaN w p pt 7 lc 2 title "Data2"
结果:
版权声明:本文内容由互联网用户自发贡献,该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务,不拥有所有权,不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容, 请发送邮件至 dio@foxmail.com 举报,一经查实,本站将立刻删除。