如何将 CsvHelper.CsvWriter 与 F# 选项类型一起使用？

如何解决如何将 CsvHelper.CsvWriter 与 F# 选项类型一起使用？

我正在尝试使用 .Net CsvHelper 库将 F# 记录集合保存到 csv 文件。问题是选项类型没有正确转换为字符串。

#r "nuget: CsvHelper"

open System.IO 
open System.Globalization
open CsvHelper

type Record = { X : string; Y : float option }

let writeString x =
    use writer = new StringWriter()
    use csv = new CsvWriter(writer,CultureInfo.InvariantCulture)
    csv.WriteRecords(x)
    writer.ToString()

[{ X = "hi"; Y = Some 1.00}
 { X = "bye"; Y = None }]
|> writeString

我希望此处的第二个数据行中的第二个字段为空值（或 CsvProvider 能够理解的任何其他 nan 值）。相反，CsvHelper 将 None 值转换为 0。

val it : string = "X,Value
hi,1
bye,0
"

我知道 FSharp.Data.CsvProvider 可以让我将这个简单的记录转换为可以保存的 CsvFile.Row。但是当你有很多字段时，这是一个糟糕的解决方案，因为很难保持 CsvFile.Row 中字段的顺序（想象 50 个浮点字段）。我更喜欢自动转换记录字段的解决方案。

解决方法

CsvHelper 中似乎没有对 F# 的内置支持，因此您可能必须编写自己的 type converter 来处理选项。这是我快速创建的一个：

open System.IO 
open System.Globalization
open CsvHelper
open CsvHelper.TypeConversion

type OptionConverter<'T>() =
    inherit DefaultTypeConverter()
    override __.ConvertToString(value,row,memberMapData) =
        match value :?> Option<'T> with
            | None -> ""
            | Some x -> base.ConvertToString(x,memberMapData)

type Record = { X : string; Y : float option }

let writeString x =
    use writer = new StringWriter()
    use csv = new CsvWriter(writer,CultureInfo.InvariantCulture)
    csv.Context.TypeConverterCache.AddConverter<Option<float>>(OptionConverter<float>())
    csv.WriteRecords(x)
    writer.ToString()

[<EntryPoint>] 
let main _ =
    [{ X = "hi"; Y = Some 1.00}
     { X = "bye"; Y = None }]
        |> writeString
        |> printfn "%s"
    0

输出为：

X,Y
hi,1
bye,

FWIW，有一些更易于从 F# 使用的 CSV 库，例如 FSharp.Data CSV provider。