在 Drools 中获取相似的对象

如何解决在 Drools 中获取相似的对象

假设我有一个来自衬衫类型的对象列表，并且每件衬衫都有一个颜色属性。 有没有办法创建一个规则，只得到相同颜色的衬衫（不管是什么颜色）？

解决方法

您正在寻找 collect function。 （链接到 Drools 文档，向下滚动一点以找到“收集”。）正如其名称所示，它收集与条件匹配的内容。

让我们假设一个简单的类 Shirt 带有一个字符串 color 变量。我们还假设工作内存中有多种衬衫实例。

rule "Collect shirts by color"
when
  Shirt( $color: color )
  $shirts: List() from collect( Shirt( color === $color ) )
then
  // $shirts will now contain all shirts of $color
end

此规则将单独考虑每件衬衫，然后收集所有其他颜色相同的衬衫。因此，如果您有红色、蓝色和绿色衬衫，那么您将至少使用该单一颜色的 $shirts 进入右侧一次。

当然，这里的问题是您将根据每件衬衫而不是根据颜色触发规则。因此，如果您有两件红色衬衫，您将对所有红色衬衫触发“then”子句两次（每件红色衬衫一次，因为每件红色衬衫都将独立满足第一个条件。）

如果您不介意这一点，那么您可以按原样使用它。但是，如果您只想对每种衬衫颜色触发一次后果，我们就必须更加狡猾。

为了让颜色成为一等公民，我们需要提取不同的衬衫颜色集（不是列表！），然后根据需要使用这些来收集我们的列表。这里我使用了 accumulate 函数；您可以在我之前分享的 Drools 文档（accumulate 直接在 collect 之后）的同一链接中阅读更多相关信息。

rule "Get shirt colors"
when
  // Get all unique shirt colors
  $colors: Set() from accumulate( Shirt( $color: color),collectSet( $color ))

  // Get one of those colors
  $color: String() from $colors

  // Find all shirts of that color
  $shirts: List() from collect( Shirt( color === $color ) )
then
  // $shirts is all shirts of $color
end

在第二条规则中，每种颜色只会触发右侧一次，因为我们首先将所有可能的颜色提炼成一组不同的独特颜色。

---

反之则更简单。如果您需要做的只是确认至少有一件颜色不同的衬衫，我们只需获取所有颜色并确认至少有 2 种不同颜色。

rule "At least one shirt of a different color"
when
  $colors: Set( size > 1 ) from accumulate( 
    Shirt( $color: color),collectSet( $color )
  )
then
  // $colors contains more than 1 color,so there's at
  // least 1 shirt present that is not the same color
  // as the rest
end