如何解决这两个 eval 之间的区别是否用常量折叠来解释?
鉴于这两个仅更改 Module::FOO()
和 FOO()
的评估。
# Symbols imported,and used locally.
eval qq[
package Foo$num;
Module->import();
my \$result = Module::FOO() * Module::FOO();
] or die $@;
# Symbols imported,not used locally referencing parent symbol.
eval qq[
package Foo$num;
Module->import();
my \$result = FOO() * FOO();
] or die $@;
为什么顶部块占用显着更少的空间?脚本和输出复制如下,
脚本
package Module {
use v5.30;
use warnings;
use constant FOO => 42;
use Exporter 'import';
our @EXPORT = ('FOO');
}
package main {
use v5.30;
use autodie;
use warnings;
$|=1;
say "Our PID is $$";
for my $num ( 0..1e5 ) {
eval qq[
package Foo$num;
Module->import();
my \$result = Module::FOO() * Module::FOO();
] or die $@;
eval qq[
package Foo$num;
Module->import();
my \$result = FOO() * FOO();
] or die $@;
}
say "DONE";
_debug();
}
sub _debug {
open my $fh,"<","/proc/$$/status";
while ( <$fh> ) {
next unless /RSS/;
print;
}
}
结果
包(命名空间)限定
RSSAnon: 78896 kB
RSSFile: 5220 kB
RSSShmem: 0 kB
本地进口
RSSAnon: 168180 kB
RSSFile: 5496 kB
RSSShmem: 0 kB
解决方法
这是 Perl 内部不断折叠的结果。这可以通过以下来自 haarg
上的 irc.freenode.net/#perl
的示例来演示,
use strict;
use warnings;
package Module {
use constant FOO => 42;
use Exporter 'import';
our @EXPORT = ('FOO');
}
my $subs = {
loc => sub {
package Foo;
Module->import();
my $result = FOO() * FOO();
},fq => sub {
package Foo;
Module->import();
my $result = Module::FOO() * Module::FOO();
},};
use Data::Dumper;
$Data::Dumper::Deparse = $Data::Dumper::Indent = 1;
print Dumper($subs);
这将导致,
$VAR1 = {
'loc' => sub {
package Foo;
use warnings;
use strict;
'Module'->import;
my $result = FOO() * FOO();
},'fq' => sub {
package Foo;
use warnings;
use strict;
'Module'->import;
my $result = 1764;
}
};
你可以看到其中一个有,
my $result = FOO() * FOO();
虽然对方有,
my $result = 1764;
如果模块被声明并且导入是在编译器阶段(在子编译的情况下)或在字符串评估的情况下在执行之前完成,你可以获得常量折叠,就像这样
BEGIN {
package Module {
use constant FOO => 42;
use Exporter 'import';
our @EXPORT = ('FOO');
}
package Foo { Module->import() }
}
版权声明:本文内容由互联网用户自发贡献,该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务,不拥有所有权,不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容, 请发送邮件至 dio@foxmail.com 举报,一经查实,本站将立刻删除。