如何解决FindComponent() 找不到组件
我创建了一个登录表单,其中包含与 Access 文件中保存的用户名相对应的按钮。这些按钮是在 OnCreate
事件中创建的,因为我不想在每次显示屏幕时都创建它们。
按钮按预期显示,我已经创建了 logon 和 logoff 过程,它们都按预期工作。
下一步是仅显示当前登录系统的用户的按钮。为此,我在 OnActivate
事件中创建了以下代码:
procedure TUserInForm.FormActivate(Sender: TObject);
var
btn : TLBButton;
begin
With UserQuery do begin;
first;
while (not eof) do begin
BtnName := FieldByName('UserName').Asstring;
Btn := TLBButton(FindComponent(BtnName));
if (Btn <> nil) then
if (FieldByName('LoggedIn').AsBoolean = True) then Btn.Visible := True else Btn.Visible := False;
next;
end;
end;
end;
但是,它没有找到任何按钮 - 它们都是 nil
。如果我删除 nil
检查,代码将引发访问冲突异常。但是,在代码中的任何时候我都不会破坏按钮或表单本身。按钮存在,因为我可以在表单上看到它们。 BtnName
变量在单元内是全局的。我已经检查过 BtnName
变量是否从表中正确填充。
我之前使用过类似的代码来查找组件,没有任何问题。事实上,我从另一个运行良好的过程(有明显的变化)“窃取”了上面显示的代码。日志显示没有错误。
解决方法
FindComponent()
搜索它被调用的组件的拥有组件列表。我假设您的 OnCreate
处理程序使用表单作为其 Owner
创建按钮。但是 with
块将导致在 FindComponent()
组件而不是 Form 上调用 UserQuery
。这将解释为什么找不到按钮。
因此,您可以:
- 改用
Self.FindComponent()
,因为OnActivate
处理程序是在 Form 上调用的,所以Self
将指向 Form:
procedure TUserInForm.FormActivate(Sender: TObject);
var
Btn : TLBButton;
BtnName : string;
begin
with UserQuery do begin
First;
while (not Eof) do begin
BtnName := FieldByName('UserName').AsString;
Btn := TLBButton(Self.FindComponent(BtnName));
if (Btn <> nil) then
Btn.Visible := FieldByName('LoggedIn').AsBoolean;
Next;
end;
end;
end;
- 完全摆脱
with
块,因为通常认为在非平凡情况下使用with
是不好的做法(这种情况是原因的一个很好的例子):立>
procedure TUserInForm.FormActivate(Sender: TObject);
var
Btn : TLBButton;
BtnName : string;
begin
UserQuery.First;
while (not UserQuery.Eof) do begin
BtnName := UserQuery.FieldByName('UserName').AsString;
Btn := TLBButton(FindComponent(BtnName));
if (Btn <> nil) then
Btn.Visible := UserQuery.FieldByName('LoggedIn').AsBoolean;
UserQuery.Next;
end;
end;
- 如果您想继续使用
with
块,您可以将按钮搜索移动到UserQuery
组件中不存在的单独函数,因此with
不会对调用该函数的组件感到困惑:
procedure TUserInForm.FormActivate(Sender: TObject);
var
Btn : TLBButton;
BtnName : string;
begin
with UserQuery do begin
First;
while (not Eof) do begin
BtnName := FieldByName('UserName').AsString;
Btn := FindButton(BtnName);
if (Btn <> nil) then
Btn.Visible := FieldByName('LoggedIn').AsBoolean;
Next;
end;
end;
end;
function TUserInForm.FindButton(const BtnName: string): TLBButton;
begin
Result := TLBButton(FindComponent(BtnName));
end;
现在,话虽如此,将创建的按钮添加到您自己管理的列表中会是一个更好的设计,而不是 VCL 代表您管理的列表。然后您将始终知道在哪里可以找到按钮。例如:
type
TUserInForm = class(TForm)
UserQuery: TQuery;
...
procedure FormActivate(Sender: TObject);
procedure FormCreate(Sender: TObject);
procedure FormDestroy(Sender: TObject);
...
private
Buttons: TList;
function FindButton(const BtnName: string): TLBButton;
...
end;
...
procedure TUserInForm.FormCreate(Sender: TObject);
var
Btn : TLBButton;
begin
Buttons := TList.Create;
...
Btn := TLBButton.Create(Self);
Btn.Name := ...
Buttons.Add(Btn);
...
end;
procedure TUserInForm.FormDestroy(Sender: TObject);
begin
Buttons.Free;
end;
procedure TUserInForm.FormActivate(Sender: TObject);
var
Btn : TLBButton;
BtnName : string;
begin
UserQuery.First;
while (not UserQuery.Eof) do begin
BtnName := UserQuery.FieldByName('UserName').AsString;
Btn := FindButton(BtnName);
if (Btn <> nil) then begin
Btn.Visible := UserQuery.FieldByName('LoggedIn').AsBoolean;
end;
UserQuery.Next;
end;
end;
function TUserInForm.FindButton(const BtnName: string): TLBButton;
var
i: integer;
begin
for i := 0 to Buttons.Count-1 do begin
Result := TLBButton(Buttons[i]);
if Result.Name = BtnName then Exit;
end;
Result := nil;
end;
版权声明:本文内容由互联网用户自发贡献,该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务,不拥有所有权,不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容, 请发送邮件至 dio@foxmail.com 举报,一经查实,本站将立刻删除。