Gnuplot：我可以在某些数据点拉伸 x 轴吗？

如何解决Gnuplot：我可以在某些数据点拉伸 x 轴吗？

我有将在 x 轴上表示的时间点向量。
其中一些时间点出现在某个星座，其他时间点出现在不同的星座。
我想将 x 缩放到 y 以作为 x=1:y=1 的第一个符号。
我想将 x 缩放到 y 作为第二个符号 x=2:y=1
因此，我将有一张 x 轴在某些点拉伸的图形“x 单位 = 双倍空间，例如 1 小时 2 厘米”，并在其他点收缩“x 单位 = 单个空间，例如 1 厘米，1 小时”
我有一个与时间数组具有相同索引的数组，其中 1 个用于单空间时间点，2 个用于双空间时间点。
我可以在 gnuplot 中绘制这个吗？ 更新：
如果在 gnuplot 中不可能，是否有任何其他库可以通过控制每个点的轴比例来绘制点？“每个点的轴比例数组和轴数据的另一个数组？？”
更新：
数据点：100 50 70 130 40 20 30 50 88 93
点宽：1 1 1 2 2 2 2 1 1 1
时间刻度：1 2 3 4 5 6 7 8 9 10
这些时间刻度应该在 x 轴上，但 1 2 3 之间的空间为 1 个单位，例如1 厘米和 4 5 6 7 之间的空间为 2 个单位，例如2 cm 然后在 8 9 10 之间为 1 个单位
数据点将是 1000000，随机 1 和 2 个单位部分。
我不知道如何绘制他们的图表。

解决方法

我仍然不确定我是否完全理解，但这是我认为您可能想要的。 因此，您的事件仅从 1、... N 开始计数。这些事件不会在常规时间步长中发生。有时在 1 秒后，有时在 2 秒后。为了绘制此图，您只需总结所有这些时间差，例如在变量 t 中。

代码：

### add variable stepsize for x-values
reset session

$Data <<EOD
 1   1  100 
 2   1   50
 3   1   70
 4   2  130
 5   2   40
 6   2   20
 7   2   30
 8   1   50
 9   1   88
10   1   93
EOD

set grid x

plot t=0 $Data u (t):(t=t+$2,$3) w lp pt 7 notitle
### end of code

结果：

添加：

这是试图理解您的意思的另一种尝试。 这就是我现在从你的问题和评论中了解到的。 你有事件，它们之间的距离如下： 1、2、3之间的距离应为1，3、4、5、6、7之间的距离应为2，7、8、9、10之间的距离应为1。

# event    1   2   3   4   5   6   7   8   9   10
# distance   1   1   2   2   2   2   1   1   1

代码：（可以跳过绘图命令的第二行。只是为了显示事件编号）

### add variable stepsize for x-values
reset session

$Data <<EOD 
 1   1  100
 2   1   50
 3   1   70
 4   2  130
 5   2   40
 6   2   20
 7   2   30
 8   1   50
 9   1   88
10   1   93
EOD

set grid x
set offsets 0,1,0

plot t=0 $Data u (t=t+$2):3 w lp pt 7 notitle,\
     t=0 ''    u (t=t+$2):3:1 w labels offset 0,1 notitle
### end of code

结果：