gnuplot：事件的直方图：timecolumn问题

如何解决gnuplot：事件的直方图：timecolumn问题

我想查看每个时间段的事件数。

我的行看起来像这样

"2020-11-11 09:15:50",field2,field3

这是我尝试过的

binwidth = 3600 # 1h in seconds
bin(t) = (t - (int(t) % binwidth) + binwidth/2)
set datafile separator ","
#set xdata time
set timefmt '"%Y-%m-%d %H:%M:%S"'
set boxwidth binwidth
plot 'Statistics.log' using (bin(timecolumn(1,'"%Y-%m-%d %H:%M:%S"'))):(1) smooth freq with boxes

我要

unknown type in magnitude()

我该如何调试此类错误？ （如何将gnuplot所看到的内容转储给timecolumn（）等？）

（gnuplot 4.6）

解决方法

首先，gnuplot 4.6中的timecolumn()是一个单参数函数，并且只允许使用列号的参数。因此，plot命令可以重写为

plot "test.dat" using (bin(timecolumn(1))):(1) smooth freq with boxes

第二，在timefmt格式中不要在双引号和尾部加上双引号。

set timefmt '%Y-%m-%d %H:%M:%S'

有关此的更多信息，请参阅“帮助数据”部分。

...

但是，在以下情况下会忽略一对双引号内的空格 计算列，因此以下数据文件行包含三列：

1.0“第二列” 3.0

最后，可以如下修改您的代码（对于gnuplot 4.6）

binwidth = 3600 # 1h in seconds
bin(t) = (t - (int(t) % binwidth) + binwidth/2)
set datafile separator ","
set xdata time
set timefmt '%Y-%m-%d %H:%M:%S'
set boxwidth binwidth
plot 'Statistics.log' using (bin(timecolumn(1))):(1) smooth freq with boxes

,

几分钟太迟了...正在测试... @ binzo基本上已经回答了。

唯一的区别：如果您的数据在日期中使用双引号

"2020-11-11 09:15:50",field2,field3`

，并且您不想更改现有数据，则必须在set timefmt中进行指定。出于某些我现在无法解释的奇怪原因，如果您set datafile separator ","会弄乱图表，但似乎没有效果。

代码：（已通过gnuplot 4.6.0测试）

### timedata in histogram (gnuplot 4.6)
reset

FILE = 'Statistics.log'
myTimeFmt = '"%Y-%m-%d %H:%M:%S"'

# create some test data
myDate = strptime(myTimeFmt,'"2020-11-11 11:11:11"')
myRandomDate(n) = myDate + 3*3600*invnorm(rand(0))
set print FILE
    do for [i=1:500] {
        print sprintf("%s,%g,%g",strftime(myTimeFmt,myRandomDate(0)),rand(0),rand(0))
    }
set print

# set datafile separator ","   # if uncommented this will messup the plot,don't know why
set xdata time
set format x "%Y-%m-%d\n%H:%M"
set timefmt '"%Y-%m-%d %H:%M:%S"'

binwidth = 3600         # 1 h in seconds
bin(t) = (t - (int(t) % binwidth) + binwidth/2)
set boxwidth binwidth
set style fill solid 0.5
set xtics 4*3600     # 4 h in seconds

plot FILE u (bin(timecolumn(1))):(1) smooth freq w boxes notitle
### end of code

结果：