gnuplot格式带有awk的时间戳记日期和时间AM PM

如何解决gnuplot格式带有awk的时间戳记日期和时间AM PM

有人可以帮我用awk格式化gnuplot的以下时间戳：

Jul 9,2020 11:59:59 AM
Jul 9,2020 12:00:00 PM
Jul 9,2020 1:22:24 PM

我一直在尝试修改上一篇文章中显示的代码示例，但是它对我不起作用。

plot "< awk '{time = $4; if(substr($5,1,2) == PM \
&& substr(time,2) < 12) add = 12; else add = 0; \
$4 = substr(time,2)+add "" substr(time,3,6); \
print $0}' Test.csv" using 1:9

我总是从gnuplot收到“ x范围无效”错误。我是编码的初学者。

在这里回答了一个类似的问题：How to read 12h (AM/PM) timeformat in gnuplot 但是我无法使代码适应我的问题。

预先感谢

解决方法

如果可以通过gnuplot进行操作，为什么还要使用awk？ 通常，这种AM / PM时间格式非常痛苦。 据我所知，gnuplot 5.2无法读取AM / PM时间作为输入，但我想应该在较新的版本中实现。

下面的代码从这里进行了稍微的修改：gnuplot: how to convert 12h time format into 24h time format? 也许仍然可以简化一点。数据被转换为合理的格式为$Data2，然后进行绘制。

代码：

### time formatting with AM/PM
reset session

$Data <<EOD
Jul 9,2020  12:22:24 AM    1.23
Jul 9,2020  11:59:59 AM    2.34
Jul 9,2020  12:00:00 PM    3.45
Jul 9,2020   1:22:24 PM    4.56
Jul 10,2020  1:22:24 PM    5.67
EOD

myTimeFmt12a = "%b %d,%Y"
myTimeFmt12b = "%H:%M:%S"
myTimeFmt24 = "%d.%m.%Y %H:%M:%S"

# change 12h am/pm format to 24h format
myTime12to24(t,p) = t+12*3600*(floor(t/3600)<12 && (p eq "PM" || p eq "pm") ? \
                    1 : floor(t/3600)==12 && (p eq "AM" || p eq "am")  ? -1 : 0)

my12to24(colDate,colHours,colAMPM) = strftime(myTimeFmt24,timecolumn(colDate,myTimeFmt12a) + \
         myTime12to24(timecolumn(colHours,myTimeFmt12b),strcol(colAMPM)))

myInputTimeFmt = "%d.%m.%Y %H:%M:%S"
myOutputTimeFmt = "%d.%m.%Y\n%H:%M:%S"
set format x myOutputTimeFmt timedate

set table $Data2
    plot $Data u (my12to24(1,4,5)):6 w table
unset table
print $Data2

plot $Data2 u (timecolumn(1,myInputTimeFmt)):3 w lp pt 7 notitle  
### end of code

添加 ：（使用gnuplot 5.4可以简化为：）

### time formatting with AM/PM (gnuplot 5.4)
reset session

$Data <<EOD
Jul 9,2020  1:22:24 PM    5.67
EOD

myInputTimeFmt = "%b %d,%Y %H:%M:%S %p"
myOutputTimeFmt = "%d.%m.%Y\n%H:%M:%S"
set format x myOutputTimeFmt timedate

plot $Data u (timecolumn(1,myInputTimeFmt)):6 w lp pt 7 notitle
### end of code

结果：