如何解决化RDF三元组中的SPARQL属性路径
是否可以将属性路径与经过修饰的rdf三元组一起使用?
我喜欢获取指定类的所有超类(存储在?class
中)。
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?class ?superclass ?supersuperclass ?supersupersuperclass
WHERE{
{
?s rdf:subject ?class .
?s rdf:predicate rdfs:subClassOf .
?s rdf:object ?superclass .
OPTIONAL {
?s1 rdf:subject ?superclass .
?s1 rdf:predicate rdfs:subClassOf .
?s1 rdf:object ?supersuperclass .
}
OPTIONAL {
?s2 rdf:subject ?supersuperclass .
?s2 rdf:predicate rdfs:subClassOf .
?s2 rdf:object ?supersupersuperclass .
}
}
}
解决方法
您可以使用中间查询,首先取消语句的具体化:
CONSTRUCT {
?s a rdfs:Class .
?o a rdfs:Class .
?s rdfs:subClassOf ?o .
}
WHERE {
?t a rdf:Statement .
?t rdf:object ?o .
?t rdf:predicate rdfs:subClassOf .
?t rdf:subject ?s .
}
然后获取所有的子类关系:
SELECT ?s ?o
WHERE {
?s a rdfs:Class .
?s rdfs:subClassOf* ?o .
}
如果您知道类没有被其他谓词相互链接,您可以使用路径:
SELECT ?s ?o
WHERE {
?s a rdfs:Class .
?o a rdfs:Class .
?s (^rdf:subject/rdf:object)* ?o .
}
版权声明:本文内容由互联网用户自发贡献,该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务,不拥有所有权,不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容, 请发送邮件至 dio@foxmail.com 举报,一经查实,本站将立刻删除。