GnuPlot在x轴上绘制从零时开始的基于时间零的数据

如何解决GnuPlot在x轴上绘制从零时开始的基于时间零的数据

我有一个数据文件，第一列是以秒为单位的时间。时间的开始是0，然后从那里开始。

我想用x轴绘制数据格式，格式为天：小时：分钟：秒。 T = 0应该映射到00：00：00：00。我不知道如何让天数从00开始而不是01。我尝试了以下方法。我还尝试将xrange设置为[-86400：173000]，但它映射到365天，而不是0天。绘制一些时间跨度的数据（从T = 0开始，可能跨越几天）是否不常见？ >

看来，GnuPlot需要一套不同的时间格式字符来进行基于零的时间绘图，而不是基于日期的时间绘图。除非它已经有了，而我却错过了。

数据

GnuPlot脚本

set xdata time
set format x "%02j:%H:%M:%S"
set timefmt "%s"
set xrange [0:173000]
plot "data" using 1:2 with lines

解决方法

我可以帮助您。 Gnuplot具有一组相对时间的单独时间格式。从零开始，处理正负间隔。在文档中很难找到，但这是“帮助time_specifiers”中的一部分。

   Format       Explanation
   %tH          +/- hours relative to time=0 (does not wrap at 24)
   %tM          +/- minutes relative to time=0
   %tS          +/- seconds associated with previous tH or tM field
时间格式示例：

日期格式说明符将以秒为单位的时间编码为时钟时间在特定的一天。因此，小时数仅从0-23开始，分钟从0-59开始，负值对应于纪元之前的日期（1970年1月1日）。为了以秒为单位报告时间值相对于时间0的小时/分钟/秒数，使用时间格式为％tH％tM％tS。报告值为-3672.50秒
   set format x                 # default date format "12/31/69 \n 22:58"
   set format x "%tH:%tM:%tS"   # "-01:01:12"
   set format x "%.2tH hours"   # "-1.02 hours"
   set format x "%tM:%.2tS"     # "-61:12.50"

将这些相对时间格式与您的样本数据一起使用，我可以得出以下结论：

$data << EOD
0 0
3600 10
7200 30
21600 50
160000 100
EOD

set xtics time format "%tH:%tM:%tS"
set title 'set xtics time format "%tH:%tM:%tS"'
set xrange [0:173000]
plot $data using 1:2 with lp

现在的问题是，没有等效的相对日格式。将此称为错误或至少缺少的功能。让我们努力手动添加格式。

secperday = 3600*24
days(t) = gprintf("%02g:",int(t)/secperday)
hours(t) = strftime("%02tH:%tM:%tS",int(t)%secperday)

# Create ten days worth of tic labels
# Every six hours with no label; once a day with full label
set xtics 6*3600 format "" 
do for [i=0:10] {
    T = day * secperday
    set xtics add ( days(T).hours(T) T )
}
plot $data using 1:2 with lp

如上面的评论中所述，一种解决方法是使用工作日，但是这会将您限制为7天。由于0秒对应于Thursday,01.01.1970 00:00:00，因此您必须减去4 days = 24*3600*4 seconds使其成为星期日（= 0）。

另一个奇怪的解决方法是使用多图并绘制两次，仅用于日期标签。您必须设置一个底边距，以精确地“重叠绘制”上一个绘图。仍然会有微调的空间。

顺便说一句：如果天数是几天，那么问题是标签上的秒数是否真正相关？

代码：

### timedate days starting from zero
reset session

$Data <<EOD
0 0
3600 10
7200 30
21600 50
160000 100
450000 222
500000 333
EOD

set multiplot layout 2,1

    # first workaround,limited to 7 days
    set format x "day %1w\n%H:%M:%S" timedate
    plot $Data u ($1-24*3600*4):2 w lp pt 7 notitle
    
    # second workaround,using multiplot
    set format x "\n%H:%M:%S" timedate
    set bmargin 3
    plot $Data u 1:2 w lp pt 7 notitle
    
    set multiplot previous
    set format x "day %s"
    set xrange[GPVAL_X_MIN/86400:GPVAL_X_MAX/86400]
    plot $Data u ($1/86400):2 w p ps 0 notitle  # point size zero,i.e. invisible

unset multiplot
### end of code

结果：

GnuPlot在x轴上绘制从零时开始的基于时间零的数据

如何解决GnuPlot在x轴上绘制从零时开始的基于时间零的数据

解决方法

相关推荐