转义XML不考虑使用XSLT命名空间并被忽略使用Mule XSLT组件

如何解决转义XML不考虑使用XSLT命名空间并被忽略使用Mule XSLT组件

我正在尝试转义xml的一部分，并使用XSLT脚本通过堆栈流获得了转义，但我能够对特定节点进行转义，但是名称空间被忽略了。示例示例如下

<root>
   <parent>test</parent>
   <parentdtl>
   <child xmlns="http://test.com">
       <element1>1</element1>
   </child>   
   </parentdtl>
   <outer>T</outer>
</root>

使用XSLT代码

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"
xmlns="http://test.com">
    <xsl:template match="*">
        <xsl:text disable-output-escaping="no">&lt;</xsl:text>
        <xsl:value-of select="name()"  />
        <xsl:apply-templates select="@*"  />
        <xsl:text disable-output-escaping="no">&gt;</xsl:text>
        <xsl:apply-templates select="node()" />
        <xsl:text disable-output-escaping="no">&lt;/</xsl:text>
        <xsl:value-of select="name()" />
        <xsl:text disable-output-escaping="no">&gt;</xsl:text>
    </xsl:template>
   <xsl:template match="@*" >
    <xsl:text disable-output-escaping="no">&#32;</xsl:text>
    <xsl:value-of select="name()" disable-output-escaping="no"/>
    <xsl:text disable-output-escaping="yes">=&amp;quot;</xsl:text>
    <xsl:value-of select="." disable-output-escaping="no"/>
    <xsl:text disable-output-escaping="yes">&amp;quot;</xsl:text>
</xsl:template>
<xsl:template match="root|parent|parentdtl|outer">
        <xsl:copy>
            <xsl:apply-templates select="@*" />
            <xsl:apply-templates />
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

但是接收到的输出中没有如下名称空间

<?xml version="1.0" encoding="UTF-8"?><root>
   <parent>test</parent>
   <parentdtl>
   &lt;child&gt;
       &lt;element1&gt;1&lt;/element1&gt;
   &lt;/child&gt;   
   </parentdtl>
   <outer>T</outer>
</root>

请告知我是否需要添加任何逻辑以包含名称空间

解决方法

有了XSLT 3支持，您可以使用serialize函数：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="#all"
    version="3.0">

   <xsl:template match="*">
       <xsl:value-of select="serialize(.)"/>
   </xsl:template>

   <xsl:template match="root|parent|parentdtl|outer">
        <xsl:copy>
            <xsl:apply-templates select="@*" />
            <xsl:apply-templates />
        </xsl:copy>
    </xsl:template> 
    
</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/jxN9PRK/1

对于serialize的旧版本（非XPath 3.1），您可能需要

   <xsl:template match="*">
       <xsl:variable name="ser-params" as="element()">
          <output:serialization-parameters xmlns:output="http://www.w3.org/2010/xslt-xquery-serialization">
             <output:omit-xml-declaration value="yes"/>
          </output:serialization-parameters>
       </xsl:variable>
       <xsl:value-of select="serialize(.,$ser-params)"/>
   </xsl:template>

避免XML声明。