如何模拟方法并返回由其回调设置的结果？

如何解决如何模拟方法并返回由其回调设置的结果？

我正在使用下面的代码来模拟UserManager。

我遇到的问题是oResult仍然为空。但是我无法在回调之外给它赋值，因为密码仅在回调内部可用。我不能只返回预定值（例如IdentityResult.Success），因为结果必须在运行时生成。

这三个问题是相似的，但它们并不能完全解决问题：

1. validate MOQ unit test method return value（这是最近的）
2. mocking a method using Moq framework doesn't return expected result
3. Moq setting method return value

所有这些与我的情况之间的区别在于，在我的方法中，方法的必需输入值仅在回调中可用。

我正在使用它来测试控制器的行为。

如何为模拟方法（在这种情况下为CreateAsync()）执行回调并返回其结果？

---

Protected Function UserManagerMock(Of TUser As Db.User,TCity as Db.City)(Users As List(Of TUser)) As Mock(Of UserManager)
  Dim oManagerMock As Mock(Of UserManager)
  Dim oStoreMock As Mock(Of IUserStore(Of TUser))
  Dim oCallback As Action(Of TUser,String)
  Dim oManager As UserManager
  Dim oResult As IdentityResult
  Dim oSetup As Expression(Of Func(Of UserManager,Task(Of IdentityResult)))

  oStoreMock = New Mock(Of IUserStore(Of TUser))
  oManagerMock = New Mock(Of UserManager)(oUserStoreMock.Object)
  oManager = oUserManagerMock.Object
  oCallback = Sub(User,Password,City)
                oResult = oManager.PasswordValidator.ValidateAsync(Password).Result

                If oResult Is IdentityResult.Success Then
                  User.PasswordHash = oManager.PasswordHasher.HashPassword(Password)
                  Users.Add(User)
                End If
              End Sub

  oManager.PasswordValidator = New PasswordValidator
  oManager.UserValidator = New UserValidator(Of TUser)(oManager)

  oSetup = Function(Manager) Manager.CreateAsync(It.IsAny(Of Db.User),It.IsAny(Of String),It.IsAny(Of Db.City))
  oUserManagerMock.Setup(oSetup).ReturnsAsync(oResult).Callback(oCallback)

  Return oManagerMock
End Function

解决方法

这可以通过完全取消回调，而使用a

来完成

Func(Of ...,Task(Of IdentityResult))

在设置的Returns()调用中。

示例：

Protected Function GetUserManager(Users As List(Of Db.User)) As UserManager
  Return Me.GetUserManagerMock(Of Db.User,Db.City)(Users).Object
End Function

Private Function GetUserManagerMock(Of TUser As Db.User,TCity As Db.City)(Users As List(Of TUser)) As Mock(Of UserManager)
  Dim oManagerMock As Mock(Of UserManager)
  Dim oStoreMock As Mock(Of IUserStore(Of TUser))
  Dim oManager As UserManager
  Dim oReturn As Func(Of TUser,String,TCity,Task(Of IdentityResult))
  Dim oResult As IdentityResult
  Dim oSetup As Expression(Of Func(Of UserManager,Task(Of IdentityResult)))

  oStoreMock = New Mock(Of IUserStore(Of TUser))
  oManagerMock = New Mock(Of UserManager)(oUserStoreMock.Object)
  oManager = oUserManagerMock.Object

  oReturn = Async Function(User,Password,City)
              If City.IsNothing Then
                oResult = IdentityResult.Failed($"{NameOf(City)} is required.")
              Else
                oResult = Await oManager.UserValidator.ValidateAsync(User)

                If oResult Is IdentityResult.Success Then
                  oResult = Await oManager.PasswordValidator.ValidateAsync(Password)

                  If oResult Is IdentityResult.Success Then
                    User.PasswordHash = oManager.PasswordHasher.HashPassword(Password)
                    Users.Add(User)

                    User.CityId = City.Id
                    User.City = City

                    City.Users.Add(User)
                  End If
                End If
              End If

              Return oResult
            End Function

  oSetup = Function(Manager) Manager.CreateAsync(It.IsAny(Of Db.User),It.IsAny(Of String),It.IsAny(Of Db.City))
  oManagerMock.Setup(oSetup).Returns(oReturn)

  Return oManagerMock
End Function

像这样使用它：

<Fact>
Public Async Function CreateUser() As Task
  Dim oUserManager As UserManager
  Dim oResult As IdentityResult
  Dim sPassword As String
  Dim oUser as Db.User
  Dim oCity as Db.City
  
  sPassword = "P@ssw0rd!"
  oUser = New Db.User With {.FirstName = "User",.LastName = "Name",.UserName = "user.name",.Email = "[e-mail]"}
  oCity = New Db.City With {.Id = 1,.Name = "BigCity",.Code = "L69CNV5"}

  oUserManager = Me.GetUserManager(Me.Users)
  oResult = Await oUserManager.CreateAsync(oUser,sPassword,oCity)

  Assert.True(oResult.Succeeded)
End Function

来源here。再次感谢stakx。