Azure问题中的Terraform / HCL

如何解决Azure问题中的Terraform / HCL

我是HCL和Terraform的新手，在将安全组和后端地址池与网络接口相关联时遇到问题。我在一个网络接口模块中创建2个网络接口：

#Create network interface for 2 VMs
resource "azurerm_network_interface" "FrontNetworkInterface" {
    count = 2
    name = "niFront${count.index}"
    location = azurerm_resource_group.PWSDevResourceGroup.location
    resource_group_name = azurerm_resource_group.PWSDevResourceGroup.name

    ip_configuration {
        name = "ipconfFrontVM"
        subnet_id = azurerm_subnet.PWSDevSubnet.id
        private_ip_address_allocation = "dynamic"
    }
}

我尝试以各种方式产生不同的错误：

尝试1：

#Connect security group to the network interface
resource "azurerm_network_interface_security_group_association" "PWSDevSecurityGroupAssoc" {
    network_interface_id = azurerm_network_interface.FrontNetworkInterface.id
    network_security_group_id = azurerm_network_security_group.PWSDevSecurityGroup.id
}

#Connect 2 backend ips to the load balancer
resource "azurerm_network_interface_backend_address_pool_association" "BackendIPAssoc" {
    network_interface_id = azurerm_network_interface.FrontNetworkInterface.id
    ip_configuration_name = "bipa"
    backend_address_pool_id = azurerm_lb_backend_address_pool.BackendIpPool.id
}

错误：

错误：缺少资源实例密钥在front.tf行85上的资源“ azurerm_network_interface_security_group_association”“ PWSDevSecurityGroupAssoc”中： 85：network_interface_id = azurerm_network_interface.FrontNetworkInterface.id 由于azurerm_network_interface.FrontNetworkInterface设置了“计数”，因此其必须在特定实例上访问属性。例如，要与引用资源的索引关联，请使用： azurerm_network_interface.FrontNetworkInterface [count.index]

错误：缺少资源实例密钥在front.tf第91行中，在资源“ azurerm_network_interface_backend_address_pool_association”“ BackendIPAssoc”中： 91：network_interface_id = azurerm_network_interface.FrontNetworkInterface.id 由于azurerm_network_interface.FrontNetworkInterface设置了“计数”，因此其必须在特定实例上访问属性。例如，要与引用资源的索引关联，请使用： azurerm_network_interface.FrontNetworkInterface [count.index]

ATTEMPT 2/3/4（使用“ [count.index]”，“ [count.index] .id”或“ [element（azurerm_network_interface.FrontNetworkInterface。*。id，count.index）]”）在上一个错误中）：

#Connect security group to the network interface
resource "azurerm_network_interface_security_group_association" "PWSDevSecurityGroupAssoc" {
    network_interface_id = azurerm_network_interface.FrontNetworkInterface[count.index]
    network_security_group_id = azurerm_network_security_group.PWSDevSecurityGroup.id
}

#Connect 2 backend ips to the load balancer
resource "azurerm_network_interface_backend_address_pool_association" "BackendIPAssoc" {
    network_interface_id = azurerm_network_interface.FrontNetworkInterface[count.index]
    ip_configuration_name = "bipa"
    backend_address_pool_id = azurerm_lb_backend_address_pool.BackendIpPool.id
}

错误（[count.index] .id和[element（azurerm_network_interface.FrontNetworkInterface。*。id，count.index）的结果相同）]

错误：在非计数上下文中引用“计数” 在front.tf行85上的资源“ azurerm_network_interface_security_group_association”“ PWSDevSecurityGroupAssoc”中： 85：network_interface_id = azurerm_network_interface.FrontNetworkInterface [count.index] “计数”对象只能在“模块”，“资源”和“数据”中使用块，并且只有在设置了“ count”参数时。

错误：在非计数上下文中引用“计数” 资源“ azurerm_network_interface_backend_address_pool_association”“ BackendIPAssoc”中的front.tf第91行： network_interface_id = azurerm_network_interface.FrontNetworkInterface [count.index] “计数”对象只能在“模块”，“资源”和“数据”中使用块，并且只有在设置了“ count”参数时。

此外，我在azurerm_virtual_machine块上收到此错误：

第162行，在资源“ azurerm_virtual_machine”“ FrontEndVirtualMachines”中： 162：admin_ssh_key { 这里不应该使用“ admin_ssh_key”类型的块。

我正在关注此处显示的内容：

https://docs.microsoft.com/en-us/azure/developer/terraform/create-linux-virtual-machine-with-infrastructure

如您所见，提供了admin_ssh_key块。我尝试使用脚本中使用的2.0版。但是，我遇到了相同的结果。

感谢您的帮助！！：）

解决方法

我承认我还没有读完整的故事，但是看起来您的尝试＃2/3/4已经非常接近了。在使用[count.index]的地方，您需要指定一个count，否则就没有索引的价值。因此，如果仅将count = 2添加到这两个资源块中，它应该可以工作。

更好的选择是将2作为变量，或使用

count = len(azurerm_network_interface.FrontNetworkInterface)

确保以后再更改2时不会出现数字不匹配的情况。

当引用使用count创建的资源时，您仍然需要添加.id。请参见以下示例。有关更多信息，请参见此link。

provider "azurerm" {
  version = "~>2.23.0"
  features {}
}

resource "azurerm_resource_group" "example" {
  name     = "example-resources"
  location = "East US"
}

resource "azurerm_virtual_network" "example" {
  name                = "vnet"
  location            = azurerm_resource_group.example.location
  resource_group_name = azurerm_resource_group.example.name
  address_space       = ["10.0.0.0/16"]
  dns_servers         = ["10.0.0.4","10.0.0.5"]
}

resource "azurerm_subnet" "example" {
  name                 = "example"
  resource_group_name  = azurerm_resource_group.example.name
  virtual_network_name = azurerm_virtual_network.example.name
  address_prefixes     = ["10.0.1.0/24"]
}

resource "azurerm_network_interface" "example" {
  count               = 2
  name                = format("int%s",count.index)
  location            = azurerm_resource_group.example.location
  resource_group_name = azurerm_resource_group.example.name

  ip_configuration {
    name                          = "ip"
    subnet_id                     = azurerm_subnet.example.id
    private_ip_address_allocation = "dynamic"
  }
}

resource "azurerm_network_security_group" "example" {
  name                = "acceptanceTestSecurityGroup1"
  location            = azurerm_resource_group.example.location
  resource_group_name = azurerm_resource_group.example.name

  security_rule {
    name                       = "test123"
    priority                   = 100
    direction                  = "Inbound"
    access                     = "Allow"
    protocol                   = "Tcp"
    source_port_range          = "*"
    destination_port_range     = "*"
    source_address_prefix      = "*"
    destination_address_prefix = "*"
  }
}

resource "azurerm_network_interface_security_group_association" "secgroup" {
  count                     = length(azurerm_network_interface.example)
  network_interface_id      = azurerm_network_interface.example[count.index].id
  network_security_group_id = azurerm_network_security_group.example.id
}

Azure问题中的Terraform / HCL

如何解决Azure问题中的Terraform / HCL

解决方法

相关推荐