无法使用Terraform向AWS ECS集群添加容量提供商

如何解决无法使用Terraform向AWS ECS集群添加容量提供商

我正在尝试使用terraform将容量提供程序添加到ECS群集中，以便它可以自动扩展。自动伸缩组需要了解群集才能在群集中创建实例，但是群集还需要通过其容量提供程序了解自动伸缩组。如何使用terraform和容量提供程序解决这种循环依赖性？

这是我用于创建集群的基础结构代码

# The ECS cluster
resource "aws_ecs_cluster" "my_cluster" {
  name = "my-cluster"
  capacity_providers = [aws_ecs_capacity_provider.my_cp.name]
}

# The capacity provider
resource "aws_ecs_capacity_provider" "my_cp" {
  name = "my-cp"

  auto_scaling_group_provider {
    auto_scaling_group_arn         = aws_autoscaling_group.my_asg.arn
    managed_termination_protection = "disABLED"

    managed_scaling {
      maximum_scaling_step_size = 1000
      minimum_scaling_step_size = 1
      status                    = "ENABLED"
      target_capacity           = 10
    }
  }
}

这是自动伸缩组及其依赖项的基础结构代码

# The image for the cluster instances 
data "aws_ssm_parameter" "instance_image" {
  name = "/aws/service/ecs/optimized-ami/amazon-linux-2/recommended/image_id"
}

# The launch config of the instances
resource "aws_launch_configuration" "my_launch_config" {
  name          = "my-launch-config"
  image_id      = data.aws_ssm_parameter.instance_image.value
  instance_type = "t3.small"
  iam_instance_profile = my_iam_profile
  security_groups = my_security_groups
  associate_public_ip_address = false
  key_name = "my-keypair"

}

# The placement group of the autosclaing group
resource "aws_placement_group" "my_pg" {
  name     = "my-pg"
  strategy = "spread"
}

# The autoscaling gorup
resource "aws_autoscaling_group" "my_asg" {
  name                      = "my-asg"
  max_size                  = 2
  min_size                  = 1
  desired_capacity          = 1

  health_check_type         = "EC2"
  health_check_grace_period = 300

  force_delete              = true
  placement_group           = aws_placement_group.my_pg.id
  launch_configuration      = aws_launch_configuration.my_launch_config.id
  vpc_zone_identifier       = my_subnets_ids


  tag {
    key                 = "Name"
    value               = "myInstance"
    propagate_at_launch = true
  }
}

应用此地形时，确实在群集上获得了一个容量提供程序，但是实例位于群集default中，而不是my-cluster中。有人会说我只需要添加

  user_data = <<EOF
    #!/bin/bash
    echo ECS_CLUSTER=${aws_ecs_cluster.my_cluster.name} >> /etc/ecs/ecs.config
  EOF

到启动配置，但是我无法在启动配置中引用该群集，因为该群集取决于容量提供程序，该容量提供程序取决于自动伸缩组，而该自动伸缩组取决于启动配置。所以我将有一个循环依赖。话虽这么说，但是如果我们无法在创建集群之后添加容量提供程序，则对terraform中的容量提供程序的支持似乎完全没有用。

解决方法

我处理此问题的方法基于这样一个事实，即您的启动配置（LC）仅需要知道集群名称。目前，您正在硬编码定义中的集群名称：

name = "my-cluster"

因此，我的方法是将variable命名为：

variable "cluster_name" {
   default = "my-cluster"
}

现在，您可以在需要的任何位置引用该名称，而无需实际创建集群：

# The ECS cluster
resource "aws_ecs_cluster" "my_cluster" {
  name = var.cluster_name
  capacity_providers = [aws_ecs_capacity_provider.my_cp.name]
}

  user_data = <<EOF
    #!/bin/bash
    echo ECS_CLUSTER=${var.cluster_name} >> /etc/ecs/ecs.config
  EOF