vb.net – 检查多个IP是否在线

我目前有一个应用程序可以ping大约50件设备并显示“向上”或“向下”箭头,具体取决于它是否在线.它的问题是,它一次ping一个,这需要一段时间.我想看看是否有办法同时ping所有这些,并在它们出现时显示结果.

当前方法示例：

If My.Computer.Network.Ping(RouterBox.Text,2000) Then
                'Online
                If GetPingMs(RouterBox.Text) < 125 Then
                    'Good ping
                    RouterPingIcon.Image = My.Resources.PingUP
                Else
                    'Bad ping
                    RouterPingIcon.Image = My.Resources.PingHIGH
                End If
            Else
                'Offline
                RouterPingIcon.Image = My.Resources.PingDOWN
            End If

注意：我在Backgroundworker中运行它.这个应用程序也是一个WinForm.由于目前我的当前ping方法有大约1000行代码,我想找到一种不涉及整个重写的方法(如果可能的话).

这是我为简单实现ping技术而制作的辅助类.它利用 System.Net.NetworkInformation.Ping class及其 SendAsync() method来执行异步ping请求.

Imports System.Net.networkinformation

Public notinheritable Class PingHelper
    Private Sub New() 'Create no instances of this class.
    End Sub

    'Events.
    Public Delegate Sub RequestsCompletedEventHandler(SentRequests As Tuple(Of String,PictureBox)()) 'The event handler signature.
    Public Shared Event RequestsCompleted As RequestsCompletedEventHandler 'The event for when all requests are done.

    'Instances of the state images.
    Private Shared Online As Image = My.Resources.Online
    Private Shared Offline As Image = My.Resources.Offline
    Private Shared HighPing As Image = My.Resources.HighPing

    'SyncLock object.
    Private Shared SyncLockObj As New Object

    'Keeping track of the requests.
    Private Shared AddressRequests As New List(Of Tuple(Of String,PictureBox)) 'The addresses of all current requests + their assigned picture Boxes.
    Private Shared CompletedRequests As Integer = 0 'Self explanatory.

    ''' <summary>
    ''' Asynchronously sends a ping request to the specified endpoint and changes the image of the StatePictureBox based on the reply.
    ''' </summary>
    ''' <param name="Address">The IP-address or hostname to ping.</param>
    ''' <param name="Timeout">The maximum number of milliseconds to wait for a reply.</param>
    ''' <param name="StatePictureBox">The PictureBox which's image to change based on the reply.</param>
    ''' <remarks></remarks>
    Public Shared Sub PingAsync(ByVal Address As String,ByVal Timeout As Integer,ByVal StatePictureBox As PictureBox)
        Using PingRequest As New Ping
            AddHandler PingRequest.PingCompleted,AddressOf PingRequest_PingCompleted 'Adds an event handler to the PingCompleted event.
            PingRequest.SendAsync(Address,Timeout,StatePictureBox) 'Start the asynchronous ping request.
            AddressRequests.Add(New Tuple(Of String,PictureBox)(Address,StatePictureBox)) 'Add the address to the list.
        End Using
    End Sub

    'Event handler for when a ping request has completed.
    Private Shared Sub PingRequest_PingCompleted(sender As Object,e As System.Net.networkinformation.PingCompletedEventArgs)
        CompletedRequests += 1 'Increment the amount of completed requests.

        If CompletedRequests >= AddressRequests.Count Then 'Are all requests done?
            RaiseEvent RequestsCompleted(AddressRequests.ToArray()) 'All current requests are done,raise the RequestsCompleted event.

            'Reset the variables.
            AddressRequests.Clear()
            CompletedRequests = 0
        End If


        If e.UserState Is nothing OrElse e.UserState.GetType() IsNot GetType(PictureBox) Then Return 'If UserToken is not a PictureBox do not continue execution.
        Dim StatePictureBox As PictureBox = DirectCast(e.UserState,PictureBox) 'Get the picture Box which's image to change.

        SyncLock SyncLockObj 'SyncLock to fix concurrency issues.
            If e.Reply.Status = IPStatus.Success Then 'Ping succeeded.
                If e.Reply.roundtripTime < 125 Then 'Is ping less than 125 ms?
                    StatePictureBox.Image = Online
                Else
                    StatePictureBox.Image = HighPing
                End If
            Else 'Ping Failed,endpoint is not online or an error occurred.
                StatePictureBox.Image = Offline
            End If
        End SyncLock
    End Sub
End Class

注意：您必须将Online / Offline / HighPing图像变量更改为您自己的图像.

您可以使用RequestsCompleted事件指示所有请求何时完成.

用法示例：

Private Sub MainForm_Load(sender As System.Object,e As System.EventArgs) Handles MyBase.Load
    AddHandler PingHelper.RequestsCompleted,AddressOf PingHelper_RequestsCompleted 'Subscribe to the "RequestsCompleted" event.
End Sub

Private Sub PingHelper_RequestsCompleted(SentRequests As Tuple(Of String,PictureBox)())
    Dim Message As String = String.Format("{0} requests completed:",SentRequests.Length) 'A message to display.
    For Each Request As Tuple(Of String,PictureBox) In SentRequests 'Iterate through all completed requests.
        Message &= Environment.NewLine & Request.Item1 'Add each IP-address/hostname on a new line in the message.
        'Request.Item1 = The address of the request.
        'Request.Item2 = The picture Box which's image will be updated by the request.
    Next
    MessageBox.Show(Message,"Requests completed",MessageBoxButtons.OK,MessageBoxIcon.information) 'display the message.
End Sub

Private Sub PingButton_Click(sender As System.Object,e As System.EventArgs) Handles PingButton.Click
    'Send 10 ping requests to different endpoints.
    PingHelper.PingAsync(TextBox1.Text,2000,PictureBox1)
    PingHelper.PingAsync(TextBox2.Text,PictureBox2)
    PingHelper.PingAsync(TextBox3.Text,PictureBox3)
    PingHelper.PingAsync(TextBox4.Text,PictureBox4)
    PingHelper.PingAsync(TextBox5.Text,PictureBox5)
    PingHelper.PingAsync(TextBox6.Text,PictureBox6)
    PingHelper.PingAsync(TextBox7.Text,PictureBox7)
    PingHelper.PingAsync(TextBox8.Text,PictureBox8)
    PingHelper.PingAsync(TextBox9.Text,PictureBox9)
    PingHelper.PingAsync(TextBox10.Text,PictureBox10)
End Sub

希望这可以帮助！