深入探讨用位掩码代替分支6：VB6速度测试

分类：VB作者：佚名

　　前面我们测试了C系列语言，验证了位掩码算法的确实性能不错。那么对于Basic系列语言，该算法的效率怎样呢？于是本文对此进行探讨。
　　VB.Net与C#一样，也是由.Net虚拟机执行的，没有多大的测试价值。所以我决定测试VB6。

一、移植要点

　　VB6的功能与C系列语言差很多。很多地方需要换另一种方法去实现，甚至不能实现。
　　要点有——
1.VB6不支持控制台程序，只支持窗口程序。所以我们的测试程序得修改为窗口程序。
2.VB6不支持指针，所以依靠数组。幸好现在的操作比较简单，用数组的性能损失不大。
3.VB6没有带符号移位运算法，所以无法实现f3_sar函数。
4.VB6和C#一样不支持宏，所以得手动实现代码。虽然可以将LIMITSU_BYTE这些宏改写为函数，但函数调用开销会影响性能。于是增加了f2_negB这个测试函数来验证这一论断。
5.VB6不支持条件运算符（?:）。所以只能利用单行If语句来实现f0_if函数。
6.虽然VB6提供了IIf函数，但它是靠变体类型来传递参数的，性能十分低下。于是增加了f1_iif这个测试函数来验证这一论断。
7.VB6的Not、And、Or、Xor运算符实际上是位运算符，可用来代替C语言中的~、&、|、^。
8.VB6默认的参数传递模式时ByRef（传引用）模式。在编写函数时，最好明确写清楚参数传递模式。因为对数组元素进行操作时，ByRef会造成额外的锁定/解锁操作，影响性能。（例如将LIMITSU_BYTE的参数改为ByRef，速度会慢一些）
9.VB6不支持函数指针或委托，所以得为每一个测试函数编写代码。


二、全部代码

　　全部代码——

' Win32 API
Private Declare Function timeGetTime Lib "winmm.dll" () As Long


' 数据规模
Private Const DATASIZE As Long = 16384   ' 128KB / (sizeof(signed short) * 4)

' 缓冲区
Private bufS(0 To DATASIZE * 4 - 1) As Integer    ' 源缓冲区。64位的颜色（4通道，每通道16位）
Private bufD(0 To DATASIZE * 4 - 1) As Byte   ' 目标缓冲区。32位的颜色（4通道，每通道8位）

' 用if分支做饱和处理
Private Sub f0_if(ByRef pbufD() As Byte,ByRef pbufS() As Integer,ByVal cnt As Long)
    Dim i As Long
    Dim p As Long   ' 当前位置
    p = 0
    For i = 0 To cnt - 1
        ' 分别对4个通道做饱和处理
        If pbufS(p) < 0 Then pbufD(p) = 0 Else If pbufS(p) > 255 Then pbufD(p) = 255 Else pbufD(p) = pbufS(p)
        p = p + 1
        If pbufS(p) < 0 Then pbufD(p) = 0 Else If pbufS(p) > 255 Then pbufD(p) = 255 Else pbufD(p) = pbufS(p)
        p = p + 1
        If pbufS(p) < 0 Then pbufD(p) = 0 Else If pbufS(p) > 255 Then pbufD(p) = 255 Else pbufD(p) = pbufS(p)
        p = p + 1
        If pbufS(p) < 0 Then pbufD(p) = 0 Else If pbufS(p) > 255 Then pbufD(p) = 255 Else pbufD(p) = pbufS(p)
        p = p + 1
    Next i
End Sub

' 用IIF函数做饱和处理
Private Sub f1_iif(ByRef pbufD() As Byte,ByVal cnt As Long)
    Dim i As Long
    Dim p As Long   ' 当前位置
    p = 0
    For i = 0 To cnt - 1
        ' 分别对4个通道做饱和处理
        pbufD(p) = IIf(pbufS(p) < 0,IIf(pbufS(p) > 255,255,pbufS(p)))
        p = p + 1
        pbufD(p) = IIf(pbufS(p) < 0,pbufS(p)))
        p = p + 1
    Next i
End Sub

' 用位掩码做饱和处理.用求负生成掩码
Private Sub f2_neg(ByRef pbufD() As Byte,ByVal cnt As Long)
    Dim i As Long
    Dim p As Long   ' 当前位置
    p = 0
    For i = 0 To cnt - 1
        ' 分别对4个通道做饱和处理
        pbufD(p) = ((pbufS(p) And (pbufS(p) >= 0) Or (pbufS(p) >= 256)) And &HFF)
        p = p + 1
        pbufD(p) = ((pbufS(p) And (pbufS(p) >= 0) Or (pbufS(p) >= 256)) And &HFF)
        p = p + 1
        pbufD(p) = ((pbufS(p) And (pbufS(p) >= 0) Or (pbufS(p) >= 256)) And &HFF)
        p = p + 1
        pbufD(p) = ((pbufS(p) And (pbufS(p) >= 0) Or (pbufS(p) >= 256)) And &HFF)
        p = p + 1
    Next i
End Sub

Private Function LIMITSU_BYTE(ByVal n As Integer) As Byte
    LIMITSU_BYTE = ((n And (n >= 0) Or (n >= 256)) And &HFF)
End Function

' 调用LIMITSU_BYTE函数
Private Sub f2_negB(ByRef pbufD() As Byte,ByVal cnt As Long)
    Dim i As Long
    Dim p As Long   ' 当前位置
    p = 0
    For i = 0 To cnt - 1
        ' 分别对4个通道做饱和处理
        pbufD(p) = LIMITSU_BYTE(pbufS(p))
        p = p + 1
        pbufD(p) = LIMITSU_BYTE(pbufS(p))
        p = p + 1
        pbufD(p) = LIMITSU_BYTE(pbufS(p))
        p = p + 1
        pbufD(p) = LIMITSU_BYTE(pbufS(p))
        p = p + 1
    Next i
End Sub

Private Sub OutLog(ByRef s As String)
    txtOut.Text = txtOut.Text & s & Chr(13) & Chr(10)
    txtOut.Refresh
    DoEvents    ' 响应界面事件
End Sub

' 进行测试
Private Sub runTest(ByVal bFull As Boolean)
    Const MaxI As Long = 3  ' 多次测试
    Const MaxJ As Long = 4000   ' 重复运算几次延长时间，避免计时精度问题
    Dim tm0 As Long,tm1 As Long    ' 执行时 间
    Dim i As Long,j As Long
    
    ' begin
    btnTest.Enabled = False
    btnTestFull.Enabled = False
    txtOut.Text = ""
    Call OutLog("== noif:VB6 ==")
    
    ' f0_if
    For i = 1 To MaxI   ' 多次测试
        tm0 = timeGetTime()
        For j = 1 To MaxJ   ' 重复运算几次延长时间，避免计时精度问题
            Call f0_if(bufD,bufS,DATASIZE)
        Next j
        tm1 = timeGetTime() - tm0
        Call OutLog("f0_if[" & i & "]:" & Chr(9) & tm1)
    Next i
    
    ' f1_iif
    If bFull Then
        For i = 1 To MaxI   ' 多次测试
            tm0 = timeGetTime()
            For j = 1 To MaxJ   ' 重复运算几次延长时间，避免计时精度问题
                Call f1_iif(bufD,DATASIZE)
            Next j
            tm1 = timeGetTime() - tm0
            Call OutLog("f1_iif[" & i & "]:" & Chr(9) & tm1)
        Next i
    End If
    
    ' f2_neg
    For i = 1 To MaxI   ' 多次测试
        tm0 = timeGetTime()
        For j = 1 To MaxJ   ' 重复运算几次延长时间，避免计时精度问题
            Call f2_neg(bufD,DATASIZE)
        Next j
        tm1 = timeGetTime() - tm0
        Call OutLog("f2_neg[" & i & "]:" & Chr(9) & tm1)
    Next i
    
    ' f2_negB
    For i = 1 To MaxI   ' 多次测试
        tm0 = timeGetTime()
        For j = 1 To MaxJ   ' 重复运算几次延长时间，避免计时精度问题
            Call f2_negB(bufD,DATASIZE)
        Next j
        tm1 = timeGetTime() - tm0
        Call OutLog("f2_negB[" & i & "]:" & Chr(9) & tm1)
    Next i
    
    ' end
    btnTest.Enabled = True
    btnTestFull.Enabled = True
End Sub

Private Sub btnTest_Click()
    Call runTest(False)
    btnTest.SetFocus
End Sub

Private Sub btnTestFull_Click()
    Call runTest(True)
    btnTestFull.SetFocus
End Sub

Private Sub Form_Load()
    Dim i As Long
    ' 初始化
    Randomize
    For i = 0 To DATASIZE * 4 - 1
        bufS(i) = CInt(Rnd() * 512) - 128   ' 使数值在 [-128,383] 区间
    Next i
    Exit Sub
End Sub

Private Sub Form_Resize()
    ' 是文本框自适应窗口尺寸
    Call txtOut.Move(0,txtOut.Top,Me.ScaleWidth,Me.ScaleHeight - txtOut.Top)
End Sub

Private Sub Form_Unload(Cancel As Integer)
    '
End Sub



三、配置与编译

3.1 配置编译优化

　　步骤如下——
1.点击菜单栏 “工程”->“属性”，打开工程属性对话框。
2.点击“编译”，切换到“编译”页面。
3.点击选择“编译为本机代码”、“代码速度优化”。

4.点击“高级优化”，打开“高级优化”对话框。
5.勾选所有的复选框，点击“确定”关闭“高级优化”对话框。

6.点击“确定”关闭工程属性对话框。


3.2 获取编译器生成的汇编代码

　　获取编译器生成的汇编代码有助于分析程序性能。虽然VB6集成开发环境没有提供该功能，但可以通过替换“C2.exe”来获得汇编代码。详见——
http://sunh.hosp.ncku.edu.tw/~cww/html/q00545.html
获取VB编译后的LST文件


3.3 编译

　　虽然可以在开发环境中按F5运行，但它实际上是以解释方式运行的。
　　应该点击菜单栏 “文件”->“发布”，生成编译后的exe。
　　因现在已经用上了“C2.exe”补丁，所以在编译过程中会提醒保存lst文件。

四、测试结果

　　运行编译后的“noifVB6.exe”。在32位winXP上的测试结果——

== noif:VB6 ==
f0_if[1]:	2844
f0_if[2]:	2859
f0_if[3]:	2844
f1_iif[1]:	83422
f1_iif[2]:	83453
f1_iif[3]:	83422
f2_neg[1]:	1078
f2_neg[2]:	1063
f2_neg[3]:	1078
f2_negB[1]:	2125
f2_negB[2]:	2125
f2_negB[3]:	2140


　　在64位win7上的测试结果——

== noif:VB6 ==
f0_if[1]:	2839
f0_if[2]:	2824
f0_if[3]:	2839
f1_iif[1]:	90137
f1_iif[2]:	90137
f1_iif[3]:	90199
f2_neg[1]:	1061
f2_neg[2]:	1061
f2_neg[3]:	1061
f2_negB[1]:	2090
f2_negB[2]:	2090
f2_negB[3]:	2090


　　硬件环境——
cpu：Intel Core i3-2310M,2100 MHz
内存：DDR3-1066


源码下载——
http://files.cnblogs.com/zyl910/noifVB6.rar （建议阅读编译器生成的汇编代码，位于“FrmNoifVB6.lst”）

版权声明：本文内容由互联网用户自发贡献，该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容， 请发送邮件至 dio@foxmail.com 举报，一经查实，本站将立刻删除。

相关推荐

VB Format函数
Format[$] ( expr [ , fmt ] ) format 返回变体型 format$ 强制返回为文本 -------------------------------- 数字类型的格式化 --------------------------------     固定格式参数：     General Number 普通数字，如可以用来去掉千位分隔号     format$("100,1
vb6/ASP FORMAT MM/DD/YYYY
VB6或者ASP 格式化时间为 MM/dd/yyyy 格式，竟然没有好的办法， Format 或者FormatDateTime 竟然结果和系统设置的区域语言的日期和时间格式相关。意思是尽管你用诸如 Format(Now, "MM/dd/yyyy")，如果系统的设置格式区域语言的日期和时间格式分隔符是"-",那他还会显示为 MM-dd-yyyy     只有拼凑： <%response.write
VB.net 捕获项目全局异常
在项目中添加如下代码：新建窗口来显示异常信息。 Namespace My ‘全局错误处理，新的解决方案直接添加本ApplicationEvents.vb 到工程即可 ‘添加后还需要一个From用来显示错误。如果到这步还不会则需要先打好基础啦 ‘======================================================== ‘以下事件
实现用VB.Net/(C#)开发K/3 BOS 插件的真正可行方法
转了这一篇文章，原来一直想用C#做k3的插件开发，vb没有C#用的爽呀，这篇文章写与2011年，看来我以前没有认真去找这个方法呀。 https://blog.csdn.net/chzjxgd/article/details/6176325 金蝶K3 BOS的插件官方是用VB6编写的，如果  能用.Net下的语言工具开发BOS插件是一件很愉快的事情，其中缘由不言而喻，而本文则是个人首创，实现在了用V
vb，wps，excel 分裂
Sub 分列() ‘以空格为分隔符，连续空格只算1个。对所选中的单元格进行处理 Dim m As Range, tmpStr As String, s As String Dim x As Integer, y As Integer, subStr As String If MsgBox("确定要分列处理吗？请确定分列的数据会覆盖它后面的单元格！", _
VB文件 hash 查看器
  窗体代码 1 Private Sub Text1_OLEDragDrop(Data As DataObject, Effect As Long, Button As Integer, Shift As Integer, X As Single, Y As Single) 2 Dim path As String, hash As String 3 For Each fil
VB.NET MYSQL DataGridView 增删改查INSERT,SELECT,UPDATE,DELETE
  Imports MySql.Data.MySqlClient Public Class Form1 ‘ GLOBAL DECLARATIONS Dim conString As String = "Server=localhost;Database=net2;Uid=root;Pwd=123456;" Dim con As New MySqlConnection
VB.NET 使用ADODB連接資料庫滙出到EXCEL
‘導入命名空間 Imports ADODB Imports Microsoft.Office.Interop   Private Sub A1() Dim Sql As String Dim Cnn As New ADODB.Connection Dim Rs As New ADODB.Recordset Dim S As String   S = "Provider=OraOLEDB.Oracl
vb.net 多线程運用 ping
Imports System.IO Imports System.Threading Imports System.Diagnostics Public Class Form1 Dim A(254) As String    Function ping(ByVal IP As Integer) As String Dim IPAddress As String IPAddress = "10.0.
VB等待进程结束
VB运行EXE程序，并等待其运行结束 参考：https://blog.csdn.net/useway/article/details/5494084 Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long Pr
vb中去掉string数组的一部分
今天碰到一个问题，登陆的时候，如果不需要验证手机号为空，则不去验证手机号 因为登陆的时候所有的验证信息都存放在一个数组里 Dim CheckUserInfo() As String ={UserBirthday, SecEmail, UserMob, UserSex, RealNameFirst, RealName, CheckCardID, CheckCardType, Contactemail
VB如何连接SQL Server数据库
在VB6.0中，数据访问接口有三种： 1、ActiveX数据对象（ADO） 2、远程数据对象（RDO） 3、数据访问对象（DAO） 1.使用ADO（ActiveX Data Objec，ActiveX数据对象）连接SQL Server 1）使用ADO控件连接 使用ADO控件的ConnectionString属性就可以连接SQL Server，该属性包含一个由分号分隔的argument=value语
Visual Basic 6.0VB6.0详细安装过程
注：大家如果没有VB6.0的安装文件，可自行百度一下下载，一般文件大小在200M左右的均为完整版的软件，可以使用。   特别提示：安装此软件的时候最好退出360杀毒软件（包括360安全卫士，电脑管家等，如果电脑上有这些软件的话），因为现如今的360杀毒软件直接会对VB6.0软件误报，这样的话就可能会在安装过程中被误报阻止而导致安装失败，或者是安装后缺乏很多必须的组件（其它的杀毒软件或安全卫士之类的
使用VB6读取数据库资源并发送邮件原创
Private Sub Form_Load() Call conndb End Sub Private Function conndb() Dim cn As New ADODB.Connection Dim rs As New ADODB.Recordset Dim strCn, sql As String Dim db_host As String Dim db_user As String
POS VB
  PPSM06S70:  Add  moddate  EDITSPRINTJOB:  MAX(TO_CHAR(ETRN.MODDATE, ‘yyyy/mm/dd/HH24:MI AM‘)) ACTUAL_SHIPDATE   4.Test Scenario (1) ：Query SQL Test DN:8016578337 SELECT CTRN.TKCTID TRUCK_ID,        
vb.net 水晶報表CrystalReport 動態設定資料庫來源
  沒有出現CrystalReportViewer時,須安裝CRforVS_13_0. 新增1個數據集,新增1個數據表,添加二列,列名要和資料庫名一樣. 修改目標Framework 修改app.config, <startup >改成<startup useLegacyV2RuntimeActivationPolicy ="true">  CrystalReport1.rpt增加數據庫專家 在表單
VB.net 与线程
Imports System.Threading Imports System Public Class Form1 Dim th1, th2 As Thread Public Sub Method1() Dim i As Integer For i = 1 To 100 If Me.Label1.BackColor =
vb.net Process32First和Module32First
Friend Const PROCESS_ALL_ACCESS = &H1F0FFF = 2035711 Friend Const PROCESS_VM_READ = &H10 Friend Const PROCESS_VM_WRITE = &H20 Friend Const PAGE_READONLY = &H2 Friend Const PAGE_READWRITE = &H4 Friend
vb.net 分割byte数组的方法SplitBytes
以下代码随手写的 并没有大量测试 效率也有待提升 如果需要C#的请自行转换 Function SplitBytes(Data As Byte(), Delimiter As Byte()) As List(Of Byte()) Dim i = 0 Dim List As New List(Of Byte()) Dim bytes As New
VB.NET连接SQL_Server实例
Imports System.Data.SqlClient Public Class Form1 REM Public conn1 As SqlConnection = New SqlConnection("server=.; Integrated Security=False;Initial Catalog= mydatabase1; User ID= sa;password")
pythonJavaScriptjavaHTMLPHPreactjsC#AndroidCSSNode.jssqlrpython-3.xMysqLjQueryc++pandasFlutterangularIOSdjangolinuxswifttypescript路由器JSON路由器设置无线路由器h3c华三华三路由器设置华三路由器电脑软件教程arraysdocker软件图文教程Cvue.jslaravelspring-boot