NSIS 命令排序

如何解决NSIS 命令排序

一些背景：

以前的安装程序工作正常，但我现在有一个客户坚持要求用户登录具有“安装”权限的帐户，因此当用户像往常一样重新登录时，无法将数据写入安装程序的目录.

我希望我的安装程序： 将文件安装到 $PROGRAMFILES 在 $PROGRAMFILES 中查找 UserDirectory.txt（包含用户文件的完整路径 - 由 .exe 使用）

如果 UserDirectory.txt 存在，则 退出（这是重新安装 - UserDirectory.txt 很好） 别的 这是一个全新的安装 打开一个对话框，允许用户选择用户文件的目录 将响应写入 UserDirectory.txt 写入用户文件

我迄今为止的代码在这里 https://1drv.ms/u/s!AiVf8kLyta3Hpj-OCYAoQt5QpQ-2?e=HLUy2N （请小声笑！）

我还以为

Install the program

Ask the user where to put the user data

是一个非常简单的想法。我错过了什么吗？

谢谢。

解决方法

这个设计听起来不正确，$PROGRAMFILES 中的任何文件都不应包含用户特定的路径，因为 $PROGRAMFILES 中安装的应用程序由计算机上的所有用户共享。

忽略这一点，您的代码包含多个问题，其中最大的一个问题是 $InstDir/$ProgramFiles/$ProgDataDir 以奇怪的组合使用有问题。

基本安装程序应如下所示：

RequestExecutionLevel admin
InstallDir "$ProgramFiles\MyApp"
;InstallDirRegKey ...

!include MUI2.nsh
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES
!insertmacro MUI_LANGUAGE English

Section
SetOutPath $InstDir ; Set File destination
WriteUninstaller "$InstDir\uninstall.exe"
File MyApp.exe
File /r "Template"
SectionEnd

Section Uninstall
...
SectionEnd

InstallDir 设置 $InstDir 的默认值。 MUI_PAGE_DIRECTORY 使用户有机会更改 $InstDir。在该页面之后，您应该只引用 $InstDir，而不是 $ProgramFiles 或任何其他变量。

使用 RequestExecutionLevel admin 的安装程序不应触摸 $PROFILE/$APPDATA/$LOCALAPPDATA，因为您正在为所有用户进行安装，而 UAC 可能会以具有不同配置文件的不同用户身份运行安装程序。

如果您有某种特定于每个用户的模板数据，应用程序而不是安装程序应该将模板/初始数据从 $InstDir 复制到 $AppData！

Certification requirements for Windows desktop apps

• 默认情况下必须将 10 个应用安装到正确的文件夹中
• 10.1 默认情况下，您的应用程序必须安装在 Program Files 文件夹中 对于 %ProgramFiles% 中的本机 32 位和 64 位应用程序，以及 %ProgramFiles(x86)% 适用于在 x64 上运行的 32 位应用程序。 用户数据或应用 出于安全考虑，数据绝不能存储在此位置 为此文件夹配置的权限。
• 10.6 您的应用必须在首次运行时写入用户数据，而不是在“每台机器”安装过程中写入用户数据 应用安装时，没有正确的用户位置 存储数据。 应用尝试修改默认关联 安装后机器级别的行为将不成功。 相反，必须在每个用户级别声明默认值，这可以防止 多个用户覆盖彼此的默认设置。

如果您想忽略此建议，这里是违反 Microsoft 准则的基本版本：

InstallDir "$ProgramFiles\MyApp"
;InstallDirRegKey ...

Var UserDataDir
!include MUI2.nsh
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_DIRECTORY
!define MUI_PAGE_HEADER_SUBTEXT "Blah blah"
!define MUI_DIRECTORYPAGE_TEXT_TOP "Blah blah. Blah blah."
!define MUI_DIRECTORYPAGE_VARIABLE $UserDataDir
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES
!insertmacro MUI_LANGUAGE English

Function .onInit
StrCpy $UserDataDir "$AppData\MyApp" ; Default
FunctionEnd

Section

SetOutPath $InstDir
WriteUninstaller "$InstDir\uninstall.exe"
File MyApp.exe

SetOutPath $UserDataDir
File Template.txt

SetDetailsView show
SetAutoClose false
DetailPrint AppInstall=$InstDir
DetailPrint UserData=$UserDataDir
SectionEnd

Section Uninstall
...
SectionEnd