NSIS - 监视器从 CMD 命令到变量的刷新率

如何解决NSIS - 监视器从 CMD 命令到变量的刷新率

这是通过在 CMD 中键入此命令来获取主显示器刷新率的方法：

wmic PATH Win32_videocontroller get currentrefreshrate

结果：

CurrentRefreshRate
144
75

第二行是我的主显示器的刷新率。我想将此数字分配给名为 $refreshrate 的变量。如何实现这一目标？

解决方法

这可以通过以下批处理文件代码完成：

@set "RefreshRate=" & for /F "tokens=2 delims==" %%I in ('%SystemRoot%\System32\wbem\wmic.exe PATH Win32_VideoController GET CurrentRefreshRate /VALUE 2^>nul') do @if not defined RefreshRate set "RefreshRate=%%I"

更容易阅读的是：

@echo off
setlocal EnableExtensions DisableDelayedExpansion
for /F "tokens=2 delims==" %%I in ('%SystemRoot%\System32\wbem\wmic.exe PATH Win32_VideoController GET CurrentRefreshRate /VALUE 2^>nul') do set "RefreshRate=%%I" & goto HaveRate
echo Failed to determine the refresh rate of primary monitor.
goto EndBatch

:HaveRate
echo Refresh rate of primary monitor is: %RefreshRate%

:EndBatch
endlocal
pause

要了解使用的命令及其工作原理，请打开 command prompt 窗口，在那里执行以下命令，并仔细阅读为每个命令显示的所有帮助页面。

echo /?
endlocal /?
for /?
goto /?
pause /?
set /?
setlocal /?
wmic /?
wmic path /?
wmic path Win32_VideoController /?
wmic path Win32_VideoController get /?

阅读有关 Using command redirection operators 的 Microsoft 文档以了解 2>nul。重定向运算符 > 必须在 FOR 命令行上用脱字符符 ^ 转义，以便在 Windows 命令解释器在执行命令 之前处理此命令行时被解释为文字字符FOR 在后台启动的单独命令进程中执行嵌入的 wmic 命令行，%ComSpec% /c 和 ' 中的命令行作为附加参数附加。

请注意，WMIC 输出始终是使用 UTF-16 Little Endian 编码的 Unicode，带有字节顺序标记 (BOM)，在处理此输出时必须考虑这一点。

我对 NSIS 一无所知，因此不知道如何从 NSIS 脚本中运行 Windows 命令并将其输出分配给 NSIS 的变量。

可以使用以下命令行运行 cmd.exe，它以第一（主）监视器的刷新率退出。

cmd.exe /E:ON /C "@for /F "tokens=2 delims==" %I in ('%SystemRoot%\System32\wbem\wmic.exe PATH Win32_VideoController GET CurrentRefreshRate /VALUE 2^>nul') do @exit /B %I"

如果命令行无法确定刷新率，则 cmd.exe 的退出代码为 0。否则 cmd.exe 返回的退出代码是第一个（主）监视器的刷新率值。

不必依赖外部工具，直接询问系统即可：

对于整个屏幕：

!include LogicLib.nsh
Section
!define /IfNDef VREFRESH 116
System::Call USER32::GetDC(p0)p.r0
System::Call GDI32::GetDeviceCaps(pr0,i${VREFRESH})i.r1
System::Call USER32::ReleaseDC(p0,pr0)
${If} $1 < 5
    StrCpy $1 "Invalid"
${EndIf}
DetailPrint "Refresh rate=$1"
SectionEnd

当前显示应用（线程）所在的位置：

!include LogicLib.nsh
Section
!define /IfNDef ENUM_CURRENT_SETTINGS -1
!define /IfNDef DM_DISPLAYFREQUENCY 0x00400000

System::Call 'USER32::GetClientRect(p0,@r1)' ; Lazy allocation of a DEVMODE
System::Call '*$1(&i68,&i2 68)'
System::Call 'USER32::EnumDisplaySettingsW(p0,i${ENUM_CURRENT_SETTINGS},pr1)i.r0'
System::Call '*$1(&i72,i.r2)'
${If} $0 <> 0
${AndIf} $2 & ${DM_DISPLAYFREQUENCY}
    System::Call '*$1(&i184,i.r3)'
    DetailPrint "Current display=$3"
${EndIf}
SectionEnd

主适配器：

!include LogicLib.nsh
Section
!define /IfNDef ENUM_CURRENT_SETTINGS -1
!define /IfNDef DM_DISPLAYFREQUENCY 0x00400000
!define /IfNDef DISPLAY_DEVICE_PRIMARY_DEVICE 4
System::Call 'USER32::GetClientRect(p0,@r1)' ; Lazy allocation of a DISPLAY_DEVICE 
StrCpy $4 0
loop:
System::Call '*$1(i840)'
System::Call 'USER32::EnumDisplayDevicesW(p0,ir4,pr1,i0)i.r0'
IntOp $4 $4 + 1
${If} $0 <> 0
    System::Call '*$1(i,&w32.r2,&w128,i.r3)'
    ${If} $3 & ${DISPLAY_DEVICE_PRIMARY_DEVICE}
        System::Call '*$1(&i68,&i2 68)' ; DEVMODE
        System::Call 'USER32::EnumDisplaySettingsW(wr2,pr1)i.r0'
        System::Call '*$1(&i72,i.r2)'
        ${If} $0 <> 0
        ${AndIf} $2 & ${DM_DISPLAYFREQUENCY}
            System::Call '*$1(&i184,i.r3)'
            DetailPrint "Primary adapter=$3"
        ${EndIf}
    ${Else}
        Goto loop
    ${EndIf}
${EndIf}
SectionEnd

如果您真的很想使用 WMI：

!include "StrFunc.nsh"  
${Using:StrFunc} StrRep 
!include LogicLib.nsh
Section
nsExec::ExecToStack '"wmic.exe" PATH Win32_videocontroller get  currentrefreshrate /all'
Pop $0
Pop $1
${StrRep} $1 $1 "currentrefreshrate" ""
loop:
    StrCpy $2 $1 1
    ${If} $2 == "$\r"
    ${OrIf} $2 == "$\n"
    ${OrIf} $2 == " "
        StrCpy $1 $1 "" 1
        Goto loop
    ${EndIf}
IntOp $2 $1 + 0 ; First number
${If} $0 = 0
    DetailPrint WMIC=$2
${EndIf}
SectionEnd

NSIS - 监视器从 CMD 命令到变量的刷新率

如何解决NSIS - 监视器从 CMD 命令到变量的刷新率

解决方法

相关推荐