对单个文件使用 ASDF 的 :around-compile

如何解决对单个文件使用 ASDF 的 :around-compile

包含 coredump 响应的 SO post 显示了如何将编译器策略应用于 ASDF 系统的组件文件：

(defsystem simple-system
  :serial t
  :around-compile (lambda (next)
                    (proclaim '(optimize (debug 3) 
                                         (safety 3)
                                         (debug 3)
                                         (speed 0)))
                    (funcall next))
  :components ((:module "src"
                        :components
                        (...))))

它还提到您可以“隐藏”单个文件，但这是如何工作的。我很困惑，因为 lambda 表达式中的 next 绑定到一个闭包。由于我只需要对几个组件文件应用优化，您如何将这些文件名赋予 :around-compile？

解决方法

您可以为系统、模块或文件添加 :around-compile。

更准确地说，如果您有一个像这样的 :file 组件：

(:file "a")

然后你可以添加：

(:file "a" :around-compile ...)

如果您只想对给定的一组文件应用优化，请将它们分组到一个模块中。您甚至可以将模块的路径名设置为 ""，以便其文件与兄弟组件位于同一目录中：

(:module #:MY-OPTIMIZED-FILES
         :depends-on (...)
         ;; SAME DIRECTORY
         :pathname ""
         :serial t
         :around-compile "my-meta-lib:around-compile"
         :components ((:file "a")
                      (:file "b")
                      (:file "c")
                      (:file "d")))

如果定义它的系统未加载，则不能引用符号，并且在 ASDF 系统的情况下，如果不先阅读定义系统的表单，则无法声明依赖项。所以你需要使用字符串来引用另一个包中的符号。

系统处理时，字符串必须引用现有符号， 因此您需要有一个不同的 .asd 文件，例如 simple-system.meta.asd，它定义了系统 "simple-system.meta"。您使用 :defsystem-depends-on 添加依赖项以确保在处理 simple-system 之前加载 meta 系统。

该系统可以是例如：

(defsystem simple-system.meta
  :depends-on ("trivial-cltl2")
  :components ((:file "meta")))

我使用 trivial-cltl2 的原因是为了能够内省全局环境中的声明并希望限制 proclaim 的影响：

(defun my-meta-lib:around-compile (next)
  (let ((opt (trivial-cltl2:declaration-information 'optimize)))
    (proclaim '(optimize (debug 3) 
                         (safety 3)
                         (debug 3)
                         (speed 0)))
    (unwind-protect (funcall next)
      (proclaim (list* 'optimize opt)))))

据我所知，proclaim 修改了全局环境，可能会影响其他文件的编译，所以我更喜欢在编译完成后恢复环境。

SBCL 为 :policy 提供了一个实验性的 with-compilation-unit 选项，专为此用例而设计，该策略在宏的动态范围内进行了修改：

(flet ((debug () (assoc 'debug (sb-cltl2:declaration-information 'optimize))))
  (list (debug)
        (with-compilation-unit (:policy '(optimize (debug 3)))
          (debug))
        (debug)))

 ; => ((DEBUG 1) (DEBUG 3) (DEBUG 1))