如何解决如何在不返回 null 的情况下运行多匹配搜索?
嗨,如果您想了解我将要参考的图表,我有一个示例查询:
CREATE (u:User {name: "Tim Cook"})-[:FOLLOWS]->(t:Thing {name: "Italy"}),(t)<-[:TAGGED]-(p:Post {name: "Post 1"})<-[:WROTE]-(u1:User {name: "Elon Musk"}),(u)-[:FOLLOWS]->(u2:User {name: "Oprah"})-[:WROTE]->(p1:Post {name: "Post 2"}),(u)-[:FOLLOWS]->(u3:User {name: "Joe Biden"})-[:WROTE]->(p2:Post {name: "Post 3"})
我正在尝试获取用户直接关注作者(“写”帖子的人)或该人关注帖子中被“标记”的事物的所有帖子。
因此,在示例查询中,如果您是 Tim Cook,您应该收到帖子 2 和 3,因为您直接关注作者,而帖子 1,因为您关注在该帖子中被标记的意大利。
我到处寻找,很难找到。降落在这里。我正在使用“可选”,这样如果用户没有关注任何人,第一个不会使整个查询崩溃,或者如果他们没有关注任何事情,第二个不会崩溃。但是,根据我在下面的做法,它为空的查询返回 Null。
因此,如果第一部分没有匹配项,第二部分没有匹配项 6,我最终会得到一个长度为 7 的数组。[null,post1,post2,...post6]。
请问我该怎么做?提前致谢!
OPTIONAL MATCH (this)-[:FOLLOWS]->(u1)-[:WROTE]->(post:Post)
RETURN post
ORDER BY post.id
UNION
OPTIONAL MATCH (this)-[:FOLLOWS]->(t:Thing)<-[:TAGGED]-(post:Post)
RETURN post
ORDER BY post.id
this
指的是上述示例中的 Tim Cook 用户节点。
如果用户关注作者(“WROTE”的用户),我也想返回。所以我想我可以添加一个“EXISTS”或者有没有办法指定哪个查询返回了一个帖子?例如。如果帖子是由上面的第一个 MATCH 返回的,那么他们显然是在关注作者。如果第二个返回,而不是第一个返回,那么他们不会。什么是最好的方法来解决这个查询/我应该如何做,拜托?提前致谢!
解决方法
您可以将路径中间的节点(用户或标签)视为通用对象,因此从那里使用多关系类型模式匹配:
MATCH (u:User {name: "Tim Cook"})
MATCH (u)-[:FOLLOWS]->(thing)-[:WROTE|TAGGED]-(p:Post)
RETURN p.name
╒════════╕
│"p.name"│
╞════════╡
│"Post 3"│
├────────┤
│"Post 2"│
├────────┤
│"Post 1"│
└────────┘
```
From there,if you want to know if the user is following the author,it's just plain logic,you return if the node in the middle is of type 'User' (which would validate the assumption since the first relationship is FOLLOWS thing)
```
MATCH (u:User {name: "Tim Cook"})
MATCH (u)-[:FOLLOWS]->(thing)-[:WROTE|TAGGED]-(p:Post)
RETURN p.name,('User' IN labels(thing)) AS followingAuthor
╒════════╤═════════════════╕
│"p.name"│"followingAuthor"│
╞════════╪═════════════════╡
│"Post 3"│true │
├────────┼─────────────────┤
│"Post 2"│true │
├────────┼─────────────────┤
│"Post 1"│false │
└────────┴─────────────────┘
```
版权声明:本文内容由互联网用户自发贡献,该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务,不拥有所有权,不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容, 请发送邮件至 dio@foxmail.com 举报,一经查实,本站将立刻删除。