具有方案的纯功能堆栈实现

如何解决具有方案的纯功能堆栈实现

我想在方案中实现功能栈。 这是我的尝试：

(define make-stack
  (letrec ((do-op
            (lambda (stack op . val)
              (cond ((eq? op 'push)
                     (lambda (op . v)
                       (do-op (cons (car val) stack) op v)))
                    ((eq? op 'pop)
                     (lambda (op . v)
                       (do-op (cdr stack) op v)))
                    ((eq? op 'print)
                     (begin (display stack)
                            (newline)
                            (lambda (op . v)
                              (do-op stack op v))))))))
    (lambda (op . val)
      (do-op '() op val))))

可以在此示例中使用堆栈：

(define s make-stack)
((((((s 'push 1) 'push 2) 'push 3) 'print) 'pop) 'print)

此示例的输出是：

((3) (2) (1))
((2) (1))

并不是我想要的，但还不错。 我想在这里问经验丰富的计划者，是否有办法使堆栈的行为更自然，例如：

(define s make-stack)
(s 'push 1)
(s 'push 2)
(s 'pop)
...

在保持功能正常的同时（因此没有可变性，没有set!）。

我想到的第一件事是继续返回不带参数的函数，但用以下方式更改每个lambda (op . v)：

(lambda ()
  (lambda (op . v)
    ...

但这不起作用，因为我们仍然需要捕获返回的函数：

> (define s make-stack)
> ((s) 'push 1)
#<procedure>

解决方法

正如阿马尔洛伊（Amalloy）所建议的那样，职能风格的原则与您的目标形成鲜明对比。做一些类似的事情并非不可能，但是-

(define (run-stack s prgm)
  (foldl (lambda (step s) (apply s step))
         s
         prgm))

(run-stack
  make-stack
 '((push 1)
   (push 2)
   (push 3)
   (print)
   (pop)
   (print)))

为了对此进行测试，我将make-stack的实现为-

(define (dispatch-stack s)
  (lambda payload
    (match payload
      ((list 'pop)
       (dispatch-stack (cdr s)))
      ((list 'push v)
       (dispatch-stack (cons v s)))
      ((list 'print)
       (println (reverse s))
       (dispatch-stack s))
      (_ (error "invalid stack operation" payload)))))

(define make-stack
  (dispatch-stack null))

输出-

'(1 2 3)
'(1 2)

我想你想看到的另一件事是Make a language in one hour: stacker。这将帮助您了解像Racket这样的语言与以前使用过的其他语言有根本的不同。

,

您的目标是矛盾的。如果s是一个堆栈，并且您的操作完全是功能正常的，则(s 'push 1)每次调用都必须返回相同的内容。要捕获更改的概念，您每次必须使用不同的s。这就是您的功能堆栈的工作方式：它将给您带来新的堆栈，并且您必须使用它来编写函数调用。