如何在orElseTry函数调用中测试尝试结果

如何解决如何在orElseTry函数调用中测试尝试结果

如何在随后的orElseTry函数调用中测试dw :: Runtime :: try（）函数调用的结果？我想匹配结果类型（错误类型），并根据上一次尝试引发的错误类型采取不同的操作，但是如果try（）结果状态为true或false，则不必匹配。

我正在尝试模仿典型的try / catch Java样式，在其中捕获各种类型的错误。

解决方法

您是否正在寻找类似的东西？您基本上需要存储try()的结果以供以后评估

%dw 2.0
output application/json
import * from dw::Runtime
var d =  "" /* change to number to work */
---
do {
    var opp = try(() -> 1 + d)
    ---
    if(opp.success) 
        opp.result
    else if(opp.error.kind == "UnexpectedFunctionCallTypesException")
        "expected error"
    else
        "unexpected error"
}

,

我不确定您会得到什么结果，但是您可以如前所述继续使用orElseTry（）进行尝试。下面的示例代码将执行以下操作：如果num是字符串/数字，它将尝试执行，如果失败，则添加1，如果是数组，则尝试附加“ 1”，否则只写num的值以考虑其他情况。

%dw 2.0
output application/json
import * from dw::Runtime
var num =  {}

---
{
    result: try(() -> num + 1) orElseTry (num ++ 1) orElseTry (num)
}

因此，将上述代码中num的值更改为以下内容：

如果num = 1

{
  "result": {
    "success": true,"result": 2
  }
}

如果num = []

{
  "result": {
    "success": true,"result": [
      1
    ]
  }
}

如果num = {}

{
  "result": {
    "success": true,"result": {
      
    }
  }
}

,

该类型的模式如何测试try / orElseTry函数捕获的错误类型，然后有条件地失败或记录一条消息，其中包含先前捕获的错误信息。如果任何先前的try / orElseTry函数成功，则此模式记录该消息。否则，故障功能之一将引发一个错误，该错误包括先前引发的错误信息，并且该错误将被错误的“种类”过滤掉。

    %dw 2.0
    output application/json
    
    import * from dw::Runtime
    
    try( () -> fail("first try") )
orElseTry fail("second try")
//orElseTry "Three times the charm!"  //uncomment to see log message
match {
    case ue if(ue.error.kind == "UserException") -> 
        ue orElse fail("ERROR: getUsers failed with a UserException error: " ++ write(ue.error,"application/json"))
    case result if(true) ->  log(
        "INFO: One of the try or orElseTry functions succeeded.",result orElse fail("Unhandled Error: " ++ write(result.error,"application/json")) 
        )
}

,

我要做的方法是使用模式匹配器，但是使用类型

%dw 2.0
output application/json

type Error<Kind <: String> = {success:false,error: {kind:Kind}}

import * from dw::Runtime
--- 
try(() -> fail("first try") )
    orElseTry fail("second try")
    // orElseTry "Three times the charm!"  //uncomment to see log message
match {
    //if(ue.error.kind == "UserException") 
    case ue is Error<"UserException"> -> 
                ue orElse 
                        fail("ERROR: getUsers failed with a UserException error: " ++ write(ue,"application/json"))
    else ->  
        log(
            "INFO: One of the try or orElseTry functions succeeded.",$ orElse fail("Unhandled Error: " ++ write($.error,"application/json")) 
        )
}