如何以编程方式判断系统是R / 3还是S / 4

如何解决如何以编程方式判断系统是R / 3还是S / 4

是否可以通过代码确定当前系统是R / 3还是S / 4？

之所以需要它，是因为我有一种方法可以返回人力资源相关数据的软件组件，但是该组件应该不同于R / 3和S / 4系统。

    DATA(lv_software_component) = mo_configuration->get_software_component( ).

    SELECT * FROM tadir INTO TABLE @DATA(lt_inftype_tables)
            WHERE pgmid  = 'R3TR'
              AND object = 'TABL'
              AND devclass IN ( SELECT devclass FROM tdevc
                                               WHERE dlvunit = @lv_software_component
                                                  OR dlvunit = 'SAP_HRGXX'
                                                  OR dlvunit = 'SAP_HRRXX' )

在R / 3上，lv_software_component应该是'SAP_HRCMX'，而在S / 4上，它应该是'S4HCMCMX'。目前，以编程方式来讲，我还不知道如何区分发行版之间的区别。

我想出的最好办法是对SY-SYSID进行硬编码，因为我知道哪些系统是S / 4，哪些不是S / 4，但这并不理想。

感谢您的帮助，谢谢！

解决方法

您可以使用下面的类方法来确定它。另一方面，is_s4h方法仅在S4系统上存在。您需要在调用方法出口之前检查它。

cl_cos_utilities=>is_s4h( )

完整的示例：

REPORT ZMKY_ISS4.
CLASS cl_oo_include_naming DEFINITION LOAD.

DATA oref TYPE REF TO if_oo_class_incl_naming.
DATA: lt_methods TYPE seop_methods_w_include,lv_clskey  TYPE seoclskey,ls_cpdkey  TYPE seocpdkey,lv_iss4    TYPE abap_bool,lt_params  TYPE abap_parmbind_tab.

lv_clskey = 'CL_COS_UTILITIES'.
oref ?= cl_oo_include_naming=>get_instance_by_cifkey( lv_clskey ).
lt_methods = oref->get_all_method_includes( ).
ls_cpdkey-clsname = lv_clskey.
ls_cpdkey-cpdname = 'IS_S4H'.
READ TABLE lt_methods WITH KEY cpdkey = ls_cpdkey TRANSPORTING NO FIELDS.
IF sy-subrc EQ 0.
  lt_params = VALUE #( ( name  = 'RV_IS_S4H'
                  kind  = cl_abap_objectdescr=>returning
                  value = REF #( lv_iss4 ) ) ).
  CALL METHOD CL_COS_UTILITIES=>('IS_S4H')
    PARAMETER-TABLE
      lt_params.
ELSE.
  lv_iss4 = abap_false.
ENDIF.

,

使用方法cl_cos_utilities=>is_s4h是一个非常不干净的解决方案，因为该方法在较早的发行版中不存在。

更干净的方法是使用功能模块SFW_IS_BFUNC_SWITCHED_ON。该功能模块检查是否在交换框架中启用了业务功能。

要检查S4HANA内部业务功能，请执行以下操作：

CALL FUNCTION 'SFW_IS_BFUNC_SWITCHED_ON'
  EXPORTING
    bfunc_name     = 'SIMPLIFY_ON_PREMISE'
  IMPORTING
    is_switched_on = is_s4.

要检查S4HANA on cloud业务功能，请执行以下操作：

CALL FUNCTION 'SFW_IS_BFUNC_SWITCHED_ON'
  EXPORTING
    bfunc_name     = 'SIMPLIFY_PUBLIC_CLOUD'
  IMPORTING
    is_switched_on = is_s4.

顺便说一句：方法cl_cos_utilities=>is_s4h实际上在内部使用此功能模块。

您可能还想检查用例中使用该功能模块来实际检测哪些HR业务功能是否更合适，而不是从系统是否具有S / 4间接获取该信息的情况下已激活。

,

有一个功能模块OCS_GET_INSTALLED_COMPS，它返回所有已安装的软件组件。请注意，它不是由SAP发布的。它曾经在旧系统中工作，但仍在S / 4HANA中工作。

,

您可以使用功能模块DELIVERY_CHCK_ACTIVE_COMPONENT来检查两个组件中的哪个处于活动状态。

如果您确实需要检查S / 4或R / 3，我也可以肯定只有S / 4系统会激活S4CORE组件。